5 REM ARKABLE LUNAR LANDING PROGRAM
 15 PRINT "BLIZI SE OKAMZIK TVEHO PRVNIHO PRISTANI"
 16 PRINT "NA MESICI"
 20 PRINT "TVYM POMOCNIKEM JE POCITAC SM 50/40"
 30 PRINT
 35 LET B=16000*.4535
 40 LET C=32500*.4535
 45 LET D=8*.4535
 50 LET D1=200*.4535
 55 PRINT "MNOZSTVI ";B;" KG PALIVA"
 60 PRINT "CELKOVA VAHA MODULU VCETNE PALIVA"
 65 PRINT "V TOMTO OKAMZIKU CINI ";C;" KG"
 70 PRINT " DOBA VOLNEHO PADU NA POVRCH MESICE"
 75 PRINT " JE 113.5 SEKUNDY OD TETO CHVILE"
 80 PRINT
 85 PRINT "MUZES REGULOVAT RYCHLOST SPALOVANI PALIVA"
 90 PRINT "OD ";D;" DO ";D1;" KG ZA SEKUNDU,KONSTRUKCE"
 95 PRINT "SKRTICIHO VENTILU NEDOVOLUJE NARIDIT"
100 PRINT "RYCHLOST SPALOVANI NA MENE NEZ ";D;" KG/SEC."
101 PRINT
102 INPUT "                                        STISKNI ENTER";
103 PRINT "MUZES VSAK UZAVRIT UPLNE VENTILY"
105 PRINT "A RYCHLOST SPALOVANI PAK BUDE 0 KG/SEC."
110 PRINT
115 PRINT "NEGATIVNI RYCHLOST SPALOVANI PALIVA UVEDE"
120 PRINT "DO CHODU PRIDAVNY MOTOREK A ZAKONCI LET"
125 PRINT
126 LET D1=0
130 PRINT "KOSMICKE CENTRUM V HOUSTONU TI PREDA "
131 PRINT "VSECHNY SVE INFORMACE O TVEM POKUSU"
140 PRINT "HODNE STESTI"
145 PRINT
147 LET D1=0
150 PRINT
155 PRINT "PRVNI RADAROVA KONTROLA"
160 PRINT
165 PRINT "ZACATEK PRISTAVACIHO MANEVRU"
176 PRINT
177 INPUT"                                        ENTER";
178 PRINT
179 PRINT
180 LET L=0
185 LET A=120
190 LET V=1
195 LET M=32500
200 LET N=16500
205 LET G=1.00000E-03
210 LET Z=1.8
215 PRINT "CAS(S)    VYSKA(KM)    RYCHLOST(KM/HOD)    PALIVO   RYCHL.SPAL."
216 FORM$ = " ###       ####.###       ####.###        ####.###"
225 PRINT USING FORM$;INT(L+.5);A*1.6094;3600*V*1.6094;.4535*(M-N)
235 INPUT "                                                    K=";K
245 LET K=K/.4535
250 LET T=10
255 IF K<0 THEN 470
260 IF K=0 THEN 295
265 IF K<8 THEN 275
270 IF K<=200 THEN 295
275 PRINT " NODNOTA K NEMOZNA,ZADEJ ZNOVU !"
290 GO TO 235
295 IF (M-N-1.00000E-03) <= 0 THEN 355
300 IF T<1.00000E-03 THEN 225
305 LET S=T
310 IF (N+S*K) <= M THEN 320
315 LET S=(M-N)/K
320 LET I0=1
325 GOTO 620
330 IF I <= 0 THEN 555
335 IF V <= 0 THEN 345
340 IF J<0 THEN 575
345 LET I0=1
350 GOTO 520
355 PRINT "PALIVO VYCERPANO ZA ";L;" SEKUND"
360 LET S=(-V+SQR(V*V+2*A*G))/G
365 LET V=V+G*S
370 LET L=L+S
375 PRINT "PRISTANI NA POVRCHU MESICE ZA ";L;" SEC."
380 LET W=3600*V
385 PRINT "RYCHLOST NARAZU NA MESIC";W*1.6094;"KM/HOD"
390 PRINT "ZUSTALO TI ";INT(M-N)*.4535;" KG PALIVA"
395 IF W>1 THEN 410
400 PRINT "PRESNE PRISTANI! BLAHOPREJEME KAPITANE!"
405 GOTO 470
410 IF W>10 THEN 425
415 PRINT "PRISTANI VELMI DOBRE,ALE NEPRESNE"
420 GOTO 470
425 IF W>=25 THEN 440
430 PRINT "PRISTANI STASTNE,LUNARNI MODUL LEHCE POSKOZEN"
435 GOTO 470
440 IF W>=60 THEN 455
445 PRINT "SPATNE PRISTANI,LUNARNI MODUL TEZCE POSKOZEN"
450 GOTO 470
455 PRINT "LITUJEME,PRISTANI SE NEPODARILO"
460 PRINT "UTVORIL JSTE VLASTNE KRATER NA POVRCHU MESICE"
465 PRINT "O HLOUBCE ";W*.227*.3048;" METRU"
467 LET D1=D1+1
470 PRINT
472 IF D1>2 THEN 709
475 REM @@@3000)
485 PRINT "CHCES SE ZUCASTNIT ZNOVU DALSIHO LETU NA MESIC"
490 PRINT "NAPIS 0-NE NEBO 1-ANO"
495 INPUT D2
500 IF D2=0 THEN 710
502 IF D1=2 THEN 706
505 PRINT "ZUCASTNIS SE NOVEHO LETU NA MESIC"
510 PRINT "OKAMZIK PRISTANI SE BLIZI"
515 GOTO 150
520 LET L=L+S
525 LET T=T-S
530 LET M=M-S*K
535 LET A=I
540 LET V=J
545 IF I0=1 THEN 295
550 IF I0=3 THEN 605
555 IF S<5.00000E-03 THEN 375
560 LET S=2*A/(V+SQR(V*V+2*A*(G-Z*K/M)))
565 LET I0=2
570 GOTO 620
575 LET W=(1-M*G/(Z*K))/2
580 LET S=M*V/(Z*K*(W+SQR(W*W+V/Z)))+5.00000E-02
585 LET I0=3
590 GOTO 620
595 IF I<=0 THEN 555
600 GOTO 520
605 IF J>=0 THEN 295
610 IF V <= 0 THEN 295
615 GOTO 575
620 LET Q=S*K/M
625 IF Q <= 0 THEN 655
630 LET J=V+G*S+Z*(-Q-(Q^2)/2-(Q^3)/3-(Q^4)/4-(Q^5)/5)
635 LET I=A-G*S*S/2-V*S+Z*S*(Q/2+Q^2/6+Q^3/12+Q^4/20+Q^5/30)
640 IF I0=1 THEN 330
645 IF I0=2 THEN 520
650 IF I0=3 THEN 595
655 LET J=V+G*S
660 LET I=A-G*S*S/2-V*S
665 GOTO 640
670 LET L=140
675 LET A=2.38234
680 LET V=.125756
685 LET M=18500
690 LET N=16500
695 LET T=10
700 PRINT
705 GOTO 205
706 PRINT
707 PRINT "POVOLUJE SE VAM JESTE JEDEN POKUS"
708 GOTO 155
709 PRINT "LITUJEME,ALE JSTE PRILIS SPATNY PILOT"
710 PRINT "KONEC LETANI!"
715 END