10 REM PROGRAM FOR BIORHYTHMICS FOR PERSONS BORN AFTER 1.3.1900
20 REM BIORYT.BAS
30 REM DATE 820518
50 I=0
80 PRINT "THIS PROGRAM WAS CREATED BY VEB MANSFELD KOMBINAT"
90 PRINT "TO PERMIT THE TRACE OF BIORHYTHMICS FOR PERSONS"
100 PRINT "BORN AFTER 1.3.1900. THE BIORHYTHMICS CONSIST OF"
110 PRINT "THREE SINUSOIDAL CURVES:"
120 PRINT :PRINT "1. MASCULINE RHYTHM: PERIOD 23 DAYS"
130 PRINT "   SIGNIFIES VITALITY, STRENGTH AND DYNAMICS."
140 PRINT "2. FEMININE RHYTHM: PERIOD 28 DAYS."
150 PRINT "   (WITHOUT ANY CONNECTION TO THE MENSTRUAL CYCLE)"
160 PRINT "   SIGNIFIES AFFECTION, SENSITIVITY,EMOTION."
170 PRINT "3. INTELLECTUAL RHYTHM: PERIOD 33 DAYS"
180 PRINT "   SIGNIFIES INTELLECTUAL POTENTIAL."
190 PRINT :PRINT "THESE THREE CURVES START ON YOUR BIRTHDAY"
200 PRINT "AND THEY WILL INTERFERE DURING YOUR WHOLE LIFE PERIOD."
230 PRINT:PRINT "PLEASE ENTER THE FOLLOWING DATES:"
240 PRINT "1. YOUR BIRTHDAY"
250 PRINT "2. STARTING DAY AND NUMBER OF DAYS FOR THE TRACES"
255 PRINT "3.NAME OF PERSON"
269 PRINT "NAME OF PERSON";
270 INPUT G$
280 PRINT "BIRTH-DAY:"
290 PRINT "DAY"
300 INPUT J
301 J9=J
310 PRINT "MONTH"
320 INPUT M
321 M9=M
330 PRINT "YEAR (EX:1947)"
340 INPUT A
341 A9=A
350 REM CALCULATE X=NRS OF DAYS FROM 1.3.1900 TO BIRTH DATE
360 IF M>2 GOTO 400
370 LET G=A-1
380 LET F=M+13
390 GOTO 420
400 LET G=A
410 LET F=M+1
420 LET X=(365.25*G)+(30.6*F)+J
440 PRINT:PRINT "START OF TRACES"
450 PRINT "DAY"
460 INPUT J
461 J8=J
480 PRINT "MONTH"
490 INPUT M
491 M8=M
500 PRINT "YEAR(EX:1982)"
510 INPUT A
511 A8=A
520 PRINT "NUMBER OF DAYS"
530 INPUT W
550 PRINT:PRINT 
570 IF M>2 GOTO 620
580 REM CALCULATE X=NRS OF DAYS FROM 1.3.1900 TO CURVE BEGINNING
590 LET G=A-1
600 LET F=M+13
610 GOTO 640
620 LET G=A
630 LET F=M+1
640 LET Y=(365.25*G)+(30.6*F)+J
650 LET Z=Y-X
660 LET Z=INT(Z)
690 PRINT "NAME OF PERSON:";G$;" WHICH WAS BORN AT";
691 PRINT J9;".";M9;".";A9
692 PRINT "YOUR LIFETIME UNTIL NOW=";
695 PRINT Z;"DAYS"
700 D1=(Z/23-INT(Z/23))*23
740 D2=(Z/28-INT(Z/28))*28
780 D3=(Z/33-INT(Z/33))*33
800 D1=INT(D1+.5)
801 D2=INT(D2+.5):D3=INT(D3+.5)
810 PRINT ""
820 PRINT "MASCULINE RHYTHM     = ***"
830 PRINT "FEMININE  RHYTHM     = OOO"
840 PRINT "INTELLECTUAL RHYTM   = +++"
850 PRINT ""
855 PRINT "TRACE STARTING AT:";J8;".";M8;".";A8
856 PRINT 
860 PRINT "PHASE DIFFERENCE ON TRACE STARTING"
870 LET F=0
880 PRINT D1;"(*)",D2;"(0)",D3;"(+)"
890 PRINT " "
900 PRINT " "
910 PRINT "DAYS                      - < 0 > +"
920 PRINT 
924 A1=6.2831
925 B1=28/A1:C1=33/A1:A1=23/A1
930 R=31+30*SIN((F+D1)/A1)
950 S=31+30*SIN((F+D2)/B1)
970 T=31+30*SIN((F+D3)/C1)
1000 PRINT F+1;" ";
1010 R$="*":S$="0":T$="+"
1020 IF R=<S THEN 1040
1030 H0=R:R=S:S=H0:H0$=R$:R$=S$:S$=H0$
1040 IF S=<T THEN 1070
1050 H0=S:S=T:T=H0:H0$=S$:S$=T$:T$=H0$
1060 GOTO 1020
1070 PRINT TAB(R);R$;
1080 PRINT TAB(S);S$;
1090 PRINT TAB(T);T$;
1170 LET F=F+1
1180 PRINT " "
1190 IF F<W GOTO 930
1220 PRINT "Do you want to guess again ";:INPUT M$
1230 IF M$="N" THEN 1250
1235 IF M$="Y" THEN 50
1240 PRINT "Please type 'Y'es or 'N'o.":GOTO 1220
1250 PRINT "Thanks for this Time.":PRINT:PRINT "Good bye !"
1270 END