1 REM  KOMENIUM n.p. Praha
2 REM  Pohyb v tihovem poli Zeme
3 REM  871109
4 REM  0001/15
5 REM  000100000/11
6 REM  100110010000000
12 REM SEREDI
15 REM SS+OU tech.smeru
100 REM VSTUPNI BOD
130 CLEAR 200:GOSUB 10000:GOSUB 11000
150 O$="                         o    "
160 P$="   D-demonstrace drah vrhu    "
170 R$="               v  ,           "
180 S$="   P-vliv prostredi na pohyb  "
190 T$="                              "
200 U$="   H-pomoc          E-konec   "
210 GOSUB 13000
220 REM
230 PRINT&27,1"          ,                   ";
240 PRINT&28,1"Stiskni klavesu: D,P,H nebo E!";:CALLHEX(F973)
250 I$=INKEY$
260 IF I$="D" THEN CALLHEX(F973):GOTO 290
270 IF I$="P" THEN CALLHEX(F973):GOTO 5000
275 IF I$="H" THEN FILL 0:GOTO 21000
280 IF I$="E" THEN ERASE:CLS:END
285 GOTO 250
290 X0=50:Y0=50
300 VX=20:VY=20
310 KO=0:AL=45:B=PI/4
320 VC=SQR(800)
330 O$="       v               v  ,"
340 P$="X,Y-souradnice  K-prostredi"
350 R$="                       ,   "
360 S$="V-celk.rychlost A-elev.uhel "
370 T$="                           "
380 U$="O-obnov H-pomoc G-graf M-Menu"
390 GOSUB 13000
400 GOSUB 12000
410 PRINT&27,1"    v       v                 ";
420 PRINT&28,1"  Zmena veliciny:X,Y,V,A,K !  ";:CALLHEX(F973)
430 I$=INKEY$
440 IF I$<>"X" THEN 450
445 Z$="Xo":GOSUB 15000:IF IX<220AND IX>=0 THEN PEN 1:GOSUB 12090:X0=IX
446 PEN 2:GOTO 330
450 IF I$<>"Y" THEN 460
455 Z$="Yo":GOSUB 15000:IF IX<100AND IX>=0 THEN PEN 1:GOSUB 12090:Y0=IX
456 PEN 2:GOTO 330
460 IF I$<>"V"THEN 470
463 Z$="Vc":GOSUB15000:IFIX>=0ANDIX<100THEN PEN1:GOSUB12090:VC=IX
466 VX=VC*COS(B):VY=VC*SIN(B):PEN 2:GOTO 330
470 IF I$<>"A"THEN 480
475 Z$="Al":GOSUB 15000:IFIX<360THEN PEN 1:GOSUB 12090:AL=IX:B=PI/180*AL
476 VX=VC*COS(B):VY=VC*SIN(B):PEN 2:GOTO 330
480 IF I$<>"K"THEN 490
485 Z$="Ko":GOSUB 15000:IFIX>=0AND IX<.1THEN PEN 1:GOSUB 12090:KO=IX
486 PEN 2:GOTO 330
490 IF I$="O"THEN FILL 0:GOSUB 12000
500 IF I$="M"THEN GOSUB 23000:FILL 0:GOTO 150
510 IF I$="H"THEN FILL 0:GOTO 22000
520 IF I$="G"THEN GOSUB 17000:CALLHEX(F973)
530 GOTO 430
5000 REM ### ODPOR PROSTREDI ##
5010 O$="                             "
5020 P$="                             "
5030 R$="          1        2         "
5040 S$="        F=-.C.S.r.v          "
5050 T$="          2                  "
5060 U$="                             "
5070 GOSUB 13000
5080 PRINT&8,1 "        ,         , ,         ";
5090 PRINT&9,1 "  Uvedeny vztah udava velikost";
5100 PRINT&10,1 " ,        ,     ,  v          ";
5110 PRINT&11,1 "sily, ktera brzdi teleso pohy-";
5120 PRINT&12,1 "   , ,           ,       v  , ";
5130 PRINT&13,1 "bujici se v hmotnem prostredi.";
5140 PRINT&14,1 "             v  ,             ";
5150 PRINT&15,1 "-C je bezrozmerny koeficient ";
5160 PRINT&16,1 " ,    ,           v           ";
5170 PRINT&17,1 "zavisly na tvaru telesa       ";
5180 PRINT&18,1 "             ov    v       2  ";
5190 PRINT&19,1 "-S je max. prurez telesa [m ]";
5200 PRINT&20,1 "     v       ,       v        ";
5210 PRINT&21,1 "ve smeru kolmem na smer pohybu";
5220 PRINT&22,1 "                   v  ,    -3 ";
5225 PRINT&23,1 "-r je hustota prostredi[kg.m ]";
5230 PRINT&24,1 "                v        -1   ";
5240 PRINT&25,1 "-v je rychlost telesa [m.s ]  ";
5250 PRINT&27,1 "               ,              ";
5260 PRINT&28,1 "     Stiskni klavesu P!       ";
5270 I$=INKEY$
5280 IF I$<>"P"THEN 5270
5290 O$="                             "
5300 P$="                             "
5310 R$="           1  C.S.r          "
5320 S$="        Ko=-.QQQQQQQ         "
5330 T$="           2    m            "
5340 U$="                             "
5350 GOSUB 13000
5360 PRINT&8,1 "                              ";
5370 PRINT&9,1 "  Tento vztah jsme odvodili   ";
5380 PRINT&10,1 "   v   v ,      v  ,   ,      ";
5390 PRINT&11,1 "z predesleho pouzitim zakona  ";
5400 PRINT&12,1 " ,                      v  v  ";
5410 PRINT&13,1 "sily a vztahu pro rovnomerne  ";
5420 PRINT&14,1 "        ,                     ";
5430 PRINT&15,1 "zrychleny pohyb. Vystupuje zde";
5440 PRINT&16,1 "              v               ";
5450 PRINT&17,1 "i m-hmotnost telesa [kg].     ";
5460 PRINT&18,1 "                   , v,       ";
5470 PRINT&19,1 "  Hodnotu Ko v druhe casti    ";
5480 PRINT&20,1 "                              ";
5500 PRINT&22,1 "                              ";
5510 PRINT&23,1 "<0.099-0.001>; tyto hodnoty   ";
5520 PRINT&24,1 "          ,                   ";
5530 PRINT&25,1 "jsou vhodne pro demonstrace.  ";
5540 PRINT&27,1 "               ,              ";
5550 PRINT&28,1 "     Stiskni klavesu P!       ";
5560 I$=INKEY$
5570 IF I$<>"P"THEN 5560
5580 GOSUB 23000:GOTO 150
10000 REM ###### RAMECEK #####
10010 CLS:ERASE
10020 PRINT"PQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQ_"
10030 PRINT&7,0;
10040 PRINT"SQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQN"
10060 PRINT&26,0;
10070 PRINT"SQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQN"
10080 PRINT&29,0"KQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQQ";
10100 PRINT"QQQQQQQQQQQQQQQQQQQQQQQQQQQJ";
10130 FOR I=1 TO 28
10140 PRINT&I,0"T";&I,63"T";
10150 NEXT I
10155 PRINT&29,0"K";
10157 PRINT&29,63"J";
10160 RETURN
11000 REM ##### GRAF.IN. #####
11010 ERASE 0
11020 LIMIT 0,507,37,196
11030 SCALE -5,220,-5,100
11040 LTYPE 2,2,2,6
11050 DRAW -1,50:DRAW 2,50,-1:DRAW 2,53:LABEL "50"
11060 DRAW 50,0:DRAW 50,-3,-1:DRAW 53,-5:LABEL "50"
11070 DRAW 100,0:DRAW 100,-3,-1:DRAW 103,-5:LABEL "100"
11080 DRAW 150,0:DRAW 150,-3,-1:DRAW 153,-5:LABEL "150"
11090 DRAW 2,90:LABEL "Y":DRAW 200,-5:LABEL "X"
11100 LIMIT 12,507,44,196
11110 SCALE 0,220,0,100
11120 RETURN
12000 REM #### TISK HODNOT ####
12010 DRAW 170,93
12020 PRINT&8,52 "Xo";INT(X0);"m"
12025 IF X0<10THEN PRINT&8,59" ";
12030 PRINT&9,52 "Yo";INT(Y0);"m"
12040 PRINT&10,52 "Vx";INT(VX);"m/s";
12045 IF VX<10AND VX>-10THEN PRINT&10,60" ";
12050 PRINT&11,52 "Vy";INT(VY);"m/s";
12055 IF VY<10AND VY>-10THEN PRINT&11,60" ";
12060 PRINT&12,52 "Vc";INT(VC);"m/s";
12065 IF VC<10THEN PRINT&12,60" ";
12070 PRINT&13,52 "Al";INT(AL);"st";
12075 IF AL<100THEN PRINT&13,60" ";
12077 IF AL<10THEN PRINT&13,59"  ";
12080 IF KO>=.01THEN PRINT&14,52 "Ko 0.0";STR$(INT(KO*1001));:GOTO 12090
12085 PRINT&14,52 "Ko 0.00";STR$(INT(KO*1001));
12090 DRAW X0+3,Y0:DRAW X0-3,Y0,-1
12100 DRAW X0,Y0-2:DRAW X0,Y0+2,-1
12110 REM DRAW X0+1,Y0-1:DRAW X0+1,Y0+2,-1
12120 RETURN
13000 REM #### VYST.MENU ####
13010 PRINT&1,1O$;
13020 PRINT&2,1P$;
13030 PRINT&3,1R$;
13040 PRINT&4,1S$;
13050 PRINT&5,1T$;
13060 PRINT&6,1U$;
13070 RETURN
15000 REM ### VSTUP VEL. ###
15010 O$="    , ,             ,   ,     "
15020 P$=" Zadavani max.5-ti mistneho   "
15030 R$=" v,         v     ,v    ,   "
15040 S$=" cisla. Ukoncit zmacknutim  "
15050 T$="   ,                          "
15060 U$=" klavesy CR .                 "
15070 GOSUB 13000
15080 PRINT&27,1"                             ";
15085 PRINT&28,1"                             ";
15090 PRINT&28,1" Zadej ";Z$;":";:CALLHEX(F973)
15100 PX=11:PY=28:GOSUB 20000
15110 CALLHEX(F973):RETURN
17000 REM ### VYPOCET-GRAF ####
17010 VK=.1*VX:VL=.1*VY
17015 SK=X0:SL=Y0:R=1
17030 VK=VK-KO*VK*ABS(VK)
17040 VL=VL-.0981
17050 VL=VL-KO*VL*ABS(VL)
17052 SL=SL+VL
17053 SK=SK+VK
17060 DRAW SK,SL,-1
17065 IF VL=<0AND R=1THEN LABEL INT(SL)+1:DRAW SK,SL:R=0
17070 IF SL=<0THEN DRAW SK,SL+10:LABEL INT(SK):RETURN
17080 GOTO 17030
20000 REM #### BEZP.INPUT ####
20010 IX$="":CO=0
20020 PRINT&PY,PX"?";:I$=INKEY$
20030 IF I$=""THEN I$=" "
20040 IF ASC(I$)=13OR CO>4 THEN IX=VAL(IX$):PRINT&PY,PX" ";:RETURN
20050 IF ASC(I$)<46OR ASC(I$)>57THEN 20020
20060 PRINT&PY,PX;I$;:CALLHEX(F973)
20070 IX$=IX$+I$:PX=PX+1:CO=CO+1:GOTO 20020
21000 REM ### HELP 1 ####
21010 PRINT&8,1 "               v,           , ";
21020 PRINT&9,1 "   Program slouzi k zobrazeni ";
21030 PRINT&10,1 " v      o  ,      o           ";
21040 PRINT&11,1 "krivek ruznych vrhu na obra-  ";
21050 PRINT&12,1 "          v  ,  v             ";
21060 PRINT&13,1 "zovce TV-prijimace.           ";
21070 PRINT&14,1 "              v ,   v       v ";
21080 PRINT&15,1 "   D-demonstracni rezim  umoz-";
21090 PRINT&16,1 "v       , ,   ,     ,         ";
21100 PRINT&17,1 "nuje zadanim zakladnich para- ";
21110 PRINT&18,1 "    o                    ,    ";
21120 PRINT&19,1 "metru pohybu vykreslit drahu  ";
21130 PRINT&20,1 "               ,       v  ,   ";
21140 PRINT&21,1 "vrhu (i v hmotnem prostredi). ";
21150 PRINT&22,1 "        ,     v   ,   ,    8  ";
21160 PRINT&23,1 "   P-poda  potrebny  vyklad k ";
21170 PRINT&24,1 "           v  ,               ";
21180 PRINT&25,1 "vlivu prostredi na pohyb.     ";
21190 PRINT&27,1 "               ,              ";
21200 PRINT&28,1 "     Stiskni klavesu H!       ";
21210 I$=INKEY$
21220 IF I$<>"H"THEN 21210
21230 GOSUB 23000:GOTO 220
22000 REM ### HELP 2 ####
22010 PRINT&8,1 "      ,  ov              ,    ";
22020 PRINT&9,1 "   Nyni muzete nastavit zak-  ";
22030 PRINT&10,1 "    ,                         ";
22040 PRINT&11,1 "ladni parametry vrhu, jako    ";
22050 PRINT&12,1 "        ,    ,           v,   ";
22060 PRINT&13,1 "polohu vychoziho bodu, poca-  ";
22070 PRINT&14,1 "  v ,                         ";
22080 PRINT&15,1 "tecni rychlost, elevaci a od- ";
22090 PRINT&16,1 "         v  ,          ,      ";
22100 PRINT&17,1 "por prostredi. Stisknutim G   ";
22110 PRINT&18,1 "   , ,           ,  v         ";
22120 PRINT&19,1 "docilite zobrazeni krivky vrhu";
22130 PRINT&20,1 "             ,v           ,   ";
22140 PRINT&21,1 "spolu s max.vyskou a max.dal- ";
22150 PRINT&22,1 "              v               ";
22160 PRINT&23,1 "kou vrhu. O maze obrazovku,   ";
22170 PRINT&24,1 "            ,     ,  , v      ";
22180 PRINT&25,1 "M poskytne zakladni vyber.    ";
22190 PRINT&27,1 "               ,              ";
22200 PRINT&28,1 "     Stiskni klavesu H!       ";
22210 I$=INKEY$
22220 IF I$<>"H"THEN 22210
22230 GOSUB 23000:GOSUB 11000:GOTO 400
23000 REM ### SEL.MAZANI ###
23010 FOR I=8TO 25
23020 PRINT&I,1 "                              ";
23030 NEXT I
23040 RETURN