1 REM KOMENIUM,n.p. PRAHA-oddeleni pocitacovych programu
2 REM 110 00 Praha 1-Truhlarska 12. (Telefon 2314934)
3 REM Evidencni cislo programu: 0106/CKL23/15
4 REM Nazev programu:FUNKCE TG, COTG
5 REM Schvaleno komisi dne: 7.3.1988
6 REM Namet navrhl:M.Opravil
7 REM Scenar vypracoval:M.Opravil
8 REM Program sestavil:M.Opravil
9 REM Metodicky text zpracoval: M.Opravil
10 REM 1.recenzi provedl:Ing.B. Brdicka
11 REM 2.recenzi provedl:RNDr.S.Schwabik,CSc
12 REM Urceno pro-typ skoly:vsechny SOS
13 REM           -predmet:matematika
14 REM           -tematicky celek:goniometrie a trigonometrie
15 REM Urceno pro-typ pocitace: IQ 151
16 REM Vybaveni pocitace moduly:1001100000
18 REM Vybaveni pocitace periferiemi:000000000
100 REM * ZACATEK *
110 CLEAR:POKE 23,100:POKE 24,50
120 REM * MENU I *
130 A=19:CLS:ERASE
140 PRINT&4,2" ,     , "
150 PRINT&5,2"ZAKLADNI MENU:"
160 PRINT&9,10"- funkce tg"
170 PRINT&11,10"- funkce cotg"
175 PRINT&13,10"- pomoc"
180 PRINT&15,10"- konec"
185 PRINT&24,1"         v,   v      ,    "
190 PRINT&25,1"Stiskni prislusnou klavesu A,B,H nebo E"
195 PRINT&9,8 CHR$(A)"A"
200 PRINT&11,8 CHR$(A)"B"
210 PRINT&13,8 CHR$(A)"H"
215 PRINT&15,8 CHR$(A)"E"
220 IF A=19 THEN A=18:GOTO 240
230 A=19
240 V$=INKEY$
245 WAIT(3)
250 IF V$="" THEN 195
255 CALLHEX(F973)
260 IF V$="H" THEN 290
265 IF V$="E" THEN ERASE:CLS:END
270 IF (V$="A" OR V$="B") THEN 310
275 CALLHEX(F973)
280 GOTO 195
290 GOSUB 5000
300 GOTO 120
310 REM * MENU II *
315 CLS:ERASE
320 PRINT&5,5"- teorie"
330 PRINT&7,5"         ,         ,"
340 PRINT&8,5"- graficke zobrazeni"
350 PRINT&10,5"      v  ,"
360 PRINT&11,5"- zkouseni"
370 PRINT&13,5"   ,         ,     ,"
380 PRINT&14,5"- navrat do zakladniho menu"
390 PRINT&17,5"- pomoc"
400 PRINT&24,1"         v,   v      ,"
410 PRINT&25,1"Stiskni prislusnou klavesu T,G,Z,M nebo H"
420 PRINT&5,3 CHR$(A)"T"
430 PRINT&8,3 CHR$(A)"G"
440 PRINT&11,3 CHR$(A)"Z"
450 PRINT&14,3 CHR$(A)"M"
460 PRINT&17,3 CHR$(A)"H"
465 WAIT(3)
470 IF A=19 THEN A=18:GOTO 490
480 A=19
490 U$=INKEY$
500 IF U$="" THEN 420
505 CALLHEX(F973)
510 IF U$="T" THEN 560
520 IF U$="G" THEN 580
530 IF U$="Z" THEN 600
540 IF U$="M" THEN 120
550 IF U$="H" THEN 620
553 CALLHEX(F973)
556 GOTO 420
560 GOSUB 7000
570 GOTO310
580 GOSUB 9000
590 GOTO 310
600 GOSUB 15000
610 GOTO 310
620 GOSUB 6000
630 GOTO 310
5000 REM * POMOC I *
5005 CLS:ERASE
5010 PRINT&4,1"                  v, "
5015 PRINT&5,1"      Program slouzi k pro-"
5020 PRINT&6,1"   v  ,      ,     "
5025 PRINT&7,1"cviceni funkci tg a cotg."
5030 PRINT&10,1"      V programu je zahrnuta "
5040 PRINT&11,1"               ,         ,"
5045 PRINT&12,1"teorie, graficke zobrazeni"
5050 PRINT&13,1"    ,  ,       v  ,"
5055 PRINT&14,1"a kratke procviceni."
5060 PRINT&16,1"         v,          "
5065 PRINT&17,1"      Tlacitkem  A nebo B si"
5070 PRINT&18,1"         v         "
5075 PRINT&19,1"zvolte pozadovanou funkci,"
5080 PRINT&20,1"       v"
5085 PRINT&21,1"ale napred"
5135 PRINT&27,1"              ,       "
5140 PRINT&28,1"    Stiskni klavesu P!"
5145 I$=INKEY$
5150 IF I$<>"P" THEN 5145
5160 CALL HEX(F973)
5200 RETURN
6000 REM * POMOC II *
6010 CLS:ERASE
6020 IF V$="A" THEN 6050
6030 PRINT&4,1"Zvolil jste funkci cotg"
6040 GOTO6060
6050 PRINT&4,1"Zvolil jste funkci tg"
6055 PRINT&6,0"            ,        v     ,"
6060 PRINT&7,0"T ... zobrazi nezbytne nutne"
6065 PRINT&8,0"               ,  "
6070 PRINT&9,0"      teoreticke znalosti"
6080 PRINT&10,0"         vv,           o  ,   o"
6090 PRINT&11,0"G ... umozni zobrazit ruzne pru-"
6095 PRINT&12,0"       v    ,         ,"
6100 PRINT&13,0"      behy Vami vybrane funkce"
6107 PRINT&15,0"           ,       ,"
6110 PRINT&16,0"Z ... spusti testovy podprogram,"
6115 PRINT&17,0"                ,  ,         v,"
6120 PRINT&18,0"      gram, ktery Vas prozkousi"
6125 PRINT&19,0"          ,     ,          ,"
6130 PRINT&20,0"      ze zakladnich znalosti"
6155 PRINT&21,0"         v ,  ,"
6160 PRINT&22,0"M ... umozni navrat do menu,"
6165 PRINT&23,0"              ov      v"
6170 PRINT&24,0"      kde si muzete zmenit"
6180 PRINT&26,0"      funkci tg na cotg nebo"
6182 PRINT&28,0"      naopak"
6185 PRINT&29,5"          ,"
6190 PRINT&30,5"Stiskni klavesu P !"
6200 I$=INKEY$
6210 IF I$<>"P" THEN 6200
6220 CALLHEX(F973)
6230 RETURN
7000 REM * TEORIE *
7010 CLS:ERASE
7015 PRINT&1,1"                         ,"
7020 IF V$="B" THEN 7110
7030 PRINT&2,1"Funkce tangens je definovana:"
7040 PRINT&4,1"              sin x"
7050 PRINT&5,1"     Y=tg x= QQQQQQQ"
7060 PRINT&6,1"              cos x"
7065 PRINT&14,0"                            v"
7070 PRINT&15,0"oborem funkce tangens je mnozina"
7075 PRINT&18,0"    ,    ,    o    "
7080 PRINT&19,0"lichych nasobku PI/2."
7100 GOTO 7175
7110 PRINT&2,1"Funkce kotangens je definovana"
7120 PRINT&4,1"               cos x"
7130 PRINT&5,1"   Y=cotg x = QQQQQQ "
7140 PRINT&6,1"               sin x"
7145 PRINT&14,0"                         v"
7150 PRINT&15,0"oborem funkce cotg je mnozina"
7155 PRINT&18,0"   ,    ,    o      "
7160 PRINT&19,0"sudych nasobku PI/2."
7175 PRINT&8,0"                      ,"
7180 PRINT&9,0"Je to funkce periodicka s perio-"
7185 PRINT&10,0"         v, ,    v     v,"
7190 PRINT&11,0"dou PI a rikame, ze patri mezi"
7195 PRINT&12,0"                   ,        v ,"
7200 PRINT&13,0"funkce goniometricke. Definicnim"
7205 PRINT&16,0" v      ,  ,   v,        v"
7210 PRINT&17,0"vsech realnych cisel krome"
7215 PRINT&20,1"   v           ,      ,"
7220 PRINT&21,1"V techto hodnotach neni funkce"
7225 PRINT&22,0"         ,"
7230 PRINT&23,0"definovana."
7245 PRINT&28,5"          ,"
7250 PRINT&29,5"Stiskni klavesu P !"
7300 I$=INKEY$
7310 IF I$<>"P" THEN 7300
7320 CALLHEX(F973)
7330 CLS
7340 RETURN
9000 REM * GRAF *
9010 P=1:R=0
9020 CLS:ERASE
9030 LIMIT0,507,60,250
9040 SCALE-1.58,6.4,-4,4
9050 LTYPE 2,2,2,6
9060 DRAW-1.58,0:DRAW6.3,0,-1
9070 DRAW0,-4:DRAW0,4,-1
9080 FOR I=1 TO 6
9090 J=-PI/2+PI/2*(I-1)
9100 DRAWJ,-0.1:DRAWJ,0.1,-1
9110 NEXT I
9120 DRAW0.2,1:LABEL"1"
9130 DRAW0.2,-1.1:LABEL"-1"
9140 FOR I=1 TO 9
9145 DRAW-0.07,(5-I):DRAW0.07,(5-I),-1
9150 NEXT I
9160 DRAW-1.6,0.3:LABEL"-PI/2"
9170 DRAW0.1,-0.4:LABEL"0"
9180 DRAW3.1,-0.4:LABEL"PI"
9190 DRAW6.1,-0.4:LABEL"2PI"
9200 DRAW6,0.4:LABEL"X"
9210 DRAW6,0.1:LABEL"->"
9220 DRAW-0.4,3.6:LABEL"y"
9230 LROT PI/2
9234 DRAW-0.1,3.6:LABEL"->"
9238 LROT 0
9240 IF R=0 AND P=0 THEN 9340
9245 X=-PI/2+0.1
9250 IF X>2*PI THEN 9340
9260 U=TAN(X)
9270 IF V$="A" THEN Y=P*U+R:GOTO9290
9280 Y=P/U+R
9290 IF Y>9 THEN DRAWX,9,-2:X=X+0.1:GOTO 9330
9300 IF Y<-9 THEN DRAWX,-9,-2:X=X+0.1:GOTO9330
9310 DRAWX,Y,+1
9320 X=X+0.05
9330 GOTO9250
9340 IF V$="B" THEN 9370
9350 PRINT&27,3"Y=A*tg(X)+B     A=";P;" B=";R
9360 GOTO 9380
9370 PRINT&27,3"Y=A*cotg(X)+B   A=";P;" B=";R
9380 PRINT&29,1"V-volba konstant  M-skok do menu  C-vymazani grafu"
9390 IF INKEY$="" THEN 9390
9410 IF INKEY$="V" THEN GOTO9450
9420 IF INKEY$="C" THEN P=0:R=0:GOTO9020
9430 IF INKEY$="M" THEN RETURN
9440 GOTO 9390
9450 FOR I=25 TO 30
9460 PRINT&I,0"                                                   "
9465 NEXT I
9467 IFV$="B"THEN 9473
9469 PRINT&25,6"Y=A*tg(x)+B"
9472 GOTO9475
9473 PRINT&25,6"Y=A*cotg(x)+B"
9475 PRINT&26,1"      , ,     "
9480 PRINT&27,1"Po zadani hodnoty stiskni CR"
9490 PRINT&29,2"A=";
9500 INPUT P
9510 PRINT&30,2"B=";
9520 INPUT R
9530 CALLHEX(F973)
9535 DRAWPI/2,4
9537 CLS
9540 GOTO 9240
14000 STOP
15000 REM  * TEST *
15005 POKE20,1
15010 CLS:ERASE
15020 SK=0
15025 PRINT"                            ,"
15030 PRINT"1. Funkce tangens je definovana:"
15035 PRINT:PRINT
15040 PRINT:PRINT"           sin x"
15050 PRINT"A.  tg Y= QQQQQQQ"
15060 PRINT"           cos x":PRINT
15070 PRINT"           cos x "
15080 PRINT"B.  tg x= QQQQQQQ"
15090 PRINT"           sin x":PRINT
15100 PRINT"           sin x"
15110 PRINT"C.  tg x= QQQQQQQ"
15120 PRINT"           cos x"
15130 GOSUB 18000
15140 IF ASC(Z$)<>67 THEN GOSUB18200:GOTO15145
15142 GOSUB18100
15145 CLS
15150 PRINT"2.  Kolik je tg(PI/4) ?"
15155 PRINT:PRINT
15160 PRINT:PRINT"A.        1"
15170 PRINT:PRINT"B.        0"
15180 PRINT:PRINT"C.       1/3"
15190 GOSUB18000
15200 IF ASC(Z$)<>65 THEN GOSUB18200:GOTO15204
15202 GOSUB18100
15204 CLS
15205 PRINT"           ,      ,"
15210 PRINT"3. Pro ktera X neni funkce "
15215 PRINT"                        ,"
15220 PRINT"     kotangens definovana ?"
15225 PRINT:PRINT
15230 PRINT:PRINT"A.       X=PI/2"
15240 PRINT:PRINT"B.       X=-PI/2"
15250 PRINT:PRINT"C.       X=PI"
15260 GOSUB18000
15270 IF ASC(Z$)<>67 THEN GOSUB18200:GOTO15274
15272 GOSUB18100
15274 CLS
15275 PRINT"                      ,"
15280 PRINT"4. Tangens 4PI se rovna"
15282 PRINT:PRINT
15285 PRINT"         ,        ,"
15290 PRINT"A.    neni definovano"
15300 PRINT:PRINT"B.         1"
15310 PRINT:PRINT"C.         0"
15320 GOSUB18000
15330 IF ASC(Z$)<>67 THEN GOSUB18200:GOTO15334
15332 GOSUB18100
15334 CLS
15335 PRINT"                             ,"
15340 PRINT"5.  Funkce kotangens je funkce ?"
15345 PRINT:POKE20,1
15347 PRINT"            ,          ,"
15350 PRINT"A.       neni periodicka":PRINT
15355 PRINT"                     ,"
15360 PRINT"B.       goniometricka":PRINT
15365 PRINT"                ,"
15370 PRINT"C.       linearni":PRINT:PRINT
15375 POKE20,2
15380 GOSUB18000
15390 IF ASC(Z$)<>66 THEN GOSUB18200:GOTO15400
15395 GOSUB18100
15400 PRINT:PRINT:PRINT:PRINT
15402 CLS
15405 PRINT"          ,     v       ,         "
15410 PRINT"  Z celkoveho poctu 5 otazek      "
15415 PRINT:PRINT"       v    v       v v"
15420 PRINT"  jste spatne zodpovedeli"
15425 PRINT:PRINT"        ,"
15430 IF 5-SK=1 THEN PRINT"    1 otazku":GOTO15460
15440 IF 5-SK=5 THEN PRINT"    5 otazek":GOTO15460
15450 PRINT"  ";5-SK;" otazky"
15455 PRINT
15460 IF (5-SK)<2 THEN 15480
15465 PRINT"   v,v           v"
15470 PRINT"  Priste se polepsi !"
15480 PRINT:PRINT:PRINT"   Stiskni klavesu P !"
15490 I$=INKEY$
15500 IF I$<>"P" THEN 15490
15505 POKE20,2
15510 RETURN
18000 REM * HODNOCENI I *
18004 PRINT&26,1"   ,          v    v      v  ,"
18005 PRINT&27,1"Spravnou odpoved urci stlacenim"
18006 PRINT&28,1"  ,"
18007 PRINT&29,1"klavesy A,B nebo C"
18010 IF INKEY$="" THEN 18020
18015 IF INKEY$="" THEN 18025
18020 GOTO 18015
18025 IF INKEY$="" THEN 18025
18030 Z$=INKEY$
18040 IF Z$>"C" OR Z$<"A" THEN 18025
18050 RETURN
18100 REM * HODNOCENI II *
18110 SK=SK+1:CALLHEX(F973)
18120 PRINT&22,9"   ,  v"
18130 PRINT&23,9"SPRAVNE"
18140 WAIT(50)
18150 RETURN
18200 REM * HODNOCENI III *
18210 PRINT&22,9"v    v"
18220 PRINT&23,9"SPATNE"
18222 CALLHEX(F973):CALLHEX(F973):CALLHEX(F973)
18230 WAIT(50)
18240 RETURN