13 REM ***********************
14 REM ***********************
15 REM ** NEMCINA LEKCE 1-5 **
16 REM ***********************
17 REM ***********************
20 REM
25 REM AUTOR: OTA ZAHORA
26 REM VERZE 1, PROSINEC 1986
30 REM
35 REM
100 REM *** HLAVNI PROGRAM ***
110 REM ----------------------
120 REM
140 REM --- INICIALIZACE ---
180 POKE 20,1
190 POKE 19,31
200 CLEAR 3000
210 CLS
220 GOSUB 1000                  :REM INICIALIZACE
230 GOSUB 2000                  :REM UVODNI OBRAZOVKA
260 POKE 10,0:POKE 9,0:POKE 8,0 :REM NULoVANI CASU
270 REM
300 REM --- PROBER TEMATA ---
310 FOR T= 1 TO PT
320 ON T GOSUB 5000,6000,7000,8000,9000
330 NEXT T
410 REM
420 REM --- VYPIS VYSLEDKY ---
440 GOSUB 11000
450 REM
460 REM --- KONEC PROGRAMU ---
470 CLS
480 POKE 20,2
490 END
500 RUN
1000 REM
1001 REM
1002 REM *** INICIALIZACE ***
1003 REM --------------------
1004 REM
1010 DEF FNM(X,Y)=X/Y-INT(X/Y)  :REM MODULO
1070 RESTORE
1100 PT=5:T=0                   :REM POCET TEMAT A C.TEMATU
1105 DIM PO(5)                  :REM POCET OTAZEK PRI TEMATECH
1110 PO(1)=4:PO(2)=9:PO(3)=6:PO(4)=4:PO(5)=9
1115 DIM PC(5,10)               :REM POCET CHYB PRI OTAZKACH
1120 DIM CH$(5,3),CH(5,3)       :REM CELKOVE HODNOCENI
1130 DIM MO$(5,10),SO$(5,10)    :REM MOZNE A SPRAVNE ODPOVEDI
1135 DIM V$(5,10)               :REM VETY NA DOPLNOVANI
1140 DIM II(5,10),D(5,10)       :REM ODKUD A V JAKE DELCE DOPLNOVAT
1145 LET CR=0:CS=0              :REM POZICE NA OBRAZ.
1150 LET MP=1                   :REM MAX. POCET POKUSU
1155 H1$="SPRAVNE"
1156 H2$="CHYBA"
1157 H3$="PRILIS MNOHO CHYB"
1158 H4$="SPRAVNA ODPOVED"
1159 H5$=" JAKO ODPOVED LZE UVEST POUZE "
1400 REM
1401 REM --- TVORENI OTAZEK ---
1405 T=1
1410 FOR I=1 TO 4
1415 READ MO$(T,I)
1420 NEXT I
1425 FOR I=1 TO 4
1430 READ SO$(T,I)
1435 NEXT I
1440 DIM V1$(4)
1450 FOR I=1 TO 4
1455 READ V1$(I),V$(T,I),II(T,I),D(T,I)
1460 NEXT I
1500 REM
1501 REM --- DOPLNOVANI CLENU ---
1505 T=2
1510 FOR I=1 TO 9
1515 READ MO$(T,I)
1520 NEXT I
1525 FOR I=1 TO 9
1530 READ SO$(T,I)
1535 NEXT I
1550 FOR I=1 TO 9
1555 READ V$(T,I),II(T,I),D(T,I)
1560 NEXT I
1600 REM
1601 REM --- ZAPORNE ODPOVEDI ---
1605 T=3
1610 FOR I=1 TO 6
1615 READ MO$(T,I)
1620 NEXT I
1625 FOR I=1 TO 6
1630 READ SO$(T,I)
1635 NEXT I
1640 DIM V3$(6)                 :REM VETY
1650 FOR I=1 TO 6
1655 READ V3$(I),V$(T,I),II(T,I),D(T,I)
1660 NEXT I
1700 REM
1701 REM --- VYBER ODPOVED ---
1705 T=4
1710 FOR I=1 TO 4
1715 READ MO$(T,I)
1720 NEXT I
1725 FOR I=1 TO 4
1730 READ SO$(T,I)
1735 NEXT I
1740 DIM V4$(4)                 :REM VETY
1750 FOR I=1 TO 4
1755 READ V4$(I),V$(T,I),II(T,I),D(T,I)
1760 NEXT I
1800 REM
1801 REM --- DOPLNOVANI PISMEN ---
1805 T=5
1850 FOR I=1 TO 9
1855 READ MO$(T,I),SO$(T,I)
1860 NEXT I
1900 REM
1990 GOSUB 2700                 :REM OSOBNI UDAJE
1999 RETURN
2000 REM
2001 REM
2002 REM *** UVODNI OBRAZOVKA ***
2003 REM ------------------------
2004 REM
2005 CLS
2010 PRINT&2,4"Dohoda o psani nekterych"
2020 PRINT&4,8"nemeckych pismen"
2030 PRINT&8,0"Nemecke ostre s je nahrazeno"
2040 PRINT&10,0"cislici 3."
2050 GOSUB 4500
2499 RETURN
2700 REM
2701 REM
2702 REM *** OSOBNI UDAJE ***
2703 REM --------------------
2704 REM
2705 CLS
2709 PRINT&4,3;"0"
2710 PRINT&4,3;"Jsem tvuj pomocnik v uceni"
2715 PRINT&6,6;"mikropocitac IQ 151"
2720 PRINT&9,0;"Jak se jmenujes ty ?"
2725 PRINT&11,0;"(po napsani zmackni vzdy CR)"
2727 POKE 17,1
2730 CR=13:CS=0:PRINT&CR,CS     :REM PARAMETRY
2735 INPUT JM$                  :REM CTI JMENO
2737 POKE 17,0
2740 PRINT&CR,CS;" "
2745 PRINT&16,0;"Z ktere jsi tridy ?"
2747 POKE 17,1
2750 CR=18:CS=0:PRINT&CR,CS     :REM PARAMETRY
2755 INPUT TR$                  :REM CTI TRIDU
2757 POKE 17,0
2760 PRINT&CR,CS;" "
2765 PRINT&21,0;"Jake je dnesni datum ?"
2767 POKE 17,1
2770 CR=23:CS=0:PRINT&CR,CS     :REM PARAMETRY
2775 INPUT DA$                  :REM CTI DATUM
2777 POKE 17,0
2780 PRINT&CR,CS;" "
2785 PRINT&27,0;"Dekuji Ti, a vzhuru do prace !"
2995 WAIT(50)
2999 RETURN
4500 REM
4501 REM *** CEKEJ NA TLACITKO ***
4502 REM -------------------------
4503 REM
4510 PRINT&29,1"Az budes chtit zacit, stiskni"
4520 PRINT&30,2"libovolnou cernou klavesu."
4530 IF INKEY$="" THEN 4530
4540 PRINT&29,0;SPC(31)
4550 PRINT&30,0;SPC(31)
4560 RETURN
4600 REM
4601 REM *** CTI Z KLAVES. A PIS NA OBR. ***
4602 REM -----------------------------------
4603 REM
4605 REM V LL JE MAX. DELKA SLOVA
4606 REM V CR A CS JE POZICE, KAM SE MA PSAT NA OBR.
4607 REM SLOVO JE UKONCENO "CR"
4610 OO$=""
4620 O$=INKEY$
4630 IF O$="" THEN 4620
4640 IF O$=CHR$(13) THEN RETURN :REM CR ?
4650 OO$=OO$ + O$
4660 IF LEN(OO$)>LL THEN RETURN :REM PRILIS DLOUHE SLOVO
4670 PRINT&CR,CS;CHR$(19);O$;CHR$(18)
4675 CS=CS+1
4680 WAIT(2)
4690 GOTO 4620
4700 REM
4701 REM *** ZABLIKEJ ***
4702 REM ----------------
4703 REM
4705 REM V LL JE POCET BLIKAJICICH ZNAKU
4706 REM V CR A CS JE POZICE, ODKUD SE MA BLIKAT
4707 REM V O$ JE BLIKAJICI RETEZEC
4709 PRINT CHR$(7);             :REM BEEP
4710 FOR N=1 TO 5
4720 PRINT&CR,CS;SPC(LL)
4730 WAIT(2)
4740 PRINT&CR,CS;CHR$(19);O$
4750 WAIT(2)
4760 NEXT N
4770 FOR N=CS TO CS+LL-1
4780 PRINT&CR,N;".";
4790 NEXT N
4795 RETURN
4800 REM
4801 REM *** VELKE PISMENO NA ZACATEK SLOVA ***
4802 REM --------------------------------------
4803 REM
4805 REM MENI 1.PISMENO O$ NA VELKE
4810 P=ASC(LEFT$(O$,1))-32
4815 IF (P<65) OR (P>90) THEN RETURN  :REM NEBYLO MALE PISMENO
4820 P$=CHR$(P)
4825 O$=RIGHT$(O$,LEN(O$)-1)
4830 O$=P$+O$
4835 RETURN
5000 REM
5001 REM
5002 REM *** TVOR OTAZKY ***
5003 REM -------------------
5004 REM
5010 CLS
5020 REM --- PIS POKYNY ---
5030 PRINT&1,1;"   v   '         '    '   '  "
5040 PRINT&2,1;"TVOR OTAZKY S DANYMI TAZACIMI"
5050 PRINT&4,12;" '     "
5060 PRINT&5,12;"ZAJMENY"
5100 PRINT&09,0"Dole na obrazovce budou uvedena"
5110 PRINT&11,0"zajmena, ktera je mozno do otaz-"
5120 PRINT&13,0"ky doplnit."
5130 PRINT&15,0"Az se napise otazka, stiskni"
5140 PRINT&17,0"klavesu s cislici uvedenou u za-"
5150 PRINT&19,0"jmena, ktere chces, aby bylo"
5160 PRINT&21,0"doplneno do otazky na misto "
5170 PRINT&23,0"tecek."
5200 GOSUB 4500                 :REM CEKEJ NA TLACITKO
5210 REM
5220 REM --- PRIPRAV OBRAZOVKU ---
5230 FOR I=7 TO 27
5232 PRINT&I,0;SPC(32);
5234 NEXT I
5240 PRINT&26,0;SPC(12);"Zajmena:"
5245 PRINT""                    :REM VYNECH RADEK
5251 FOR I=1 TO 4
5252 PRINT CHR$(19);I;CHR$(18);"=";MO$(T,I);" ";
5253 NEXT I
5300 REM
5310 REM --- PIS VETY A CTI ZAJMENA ---
5315 CR=12
5320 FOR I=1 TO PO(T)
5330 PRINT&CR,0;V1$(I)          :REM OZNAMOVACI VETA
5332 PRINT&CR+1,0;SPC(31)       :REM VYNECH RADEK
5335 CR=CR+2
5340 H6$="        "+"VYBER ZAJMENO"+"         "
5350 GOSUB 10000                :REM PRECTI A OTESTUJ ODPOVED
5440 CR=CR-2
5445 PRINT&CR,0;SPC(31)         :REM VYMAZ RADEK
5447 PRINT&CR+2,0;SPC(31)       :REM VYMAZ RADEK
5450 NEXT I
5455 WAIT(10)
5460 RETURN
6000 REM
6001 REM
6002 REM *** DOPLN CLEN NEBO ZAJMENO ***
6003 REM -------------------------------
6004 REM
6010 CLS
6020 REM --- PIS POKYNY ---
6030 PRINT&1,1;"       v v          '        "
6040 PRINT&2,1;"   DOPLN CLEN NEBO ZAJMENO   "
6100 PRINT&07,0"Dole na obrazovce budou uvedeny"
6110 PRINT&09,0"cleny a zajmena, ktera je moz-"
6120 PRINT&11,0"no do vety doplnit."
6130 PRINT&13,0"Az se veta napise, stiskni kla-"
6140 PRINT&15,0"vesu s cislici uvedenou u slova,"
6150 PRINT&17,0"ktere ma byt doplneno do vety"
6160 PRINT&19,0"na misto tecek."
6170 PRINT&21,0"Vety napsane na obrazovce na se-"
6180 PRINT&23,0"be navazuji. Podle toho je nut-"
6190 PRINT&25,0"ne cleny a zajmena doplnovat."
6200 GOSUB 4500                 :REM CEKEJ NA TLACITKO
6210 REM
6220 REM --- PRIPRAV OBRAZOVKU ---
6230 FOR I=7 TO 27
6232 PRINT&I,0;SPC(32);
6234 NEXT I
6240 PRINT&24,0;SPC(5);"Cleny a zajmena:"
6245 PRINT""                    :REM VYNECH RADEK
6250 FOR I=1 TO 3
6251 PRINT CHR$(19);I;CHR$(18);"=";MO$(T,I);" ";
6252 NEXT I
6253 PRINT""   :REM NOVY RADEK
6254 FOR I=4 TO 6
6255 PRINT CHR$(19);I;CHR$(18);"=";MO$(T,I);" ";
6256 NEXT I
6257 PRINT""   :REM NOVY RADEK
6258 FOR I=7 TO 9
6259 PRINT CHR$(19);I;CHR$(18);"=";MO$(T,I);" ";
6260 NEXT I
6300 REM
6310 REM --- PIS VETY A CTI CLENY ---
6315 CR=12
6320 FOR I=1 TO PO(T)
6340 H6$="    "+"VYBER ZAJMENO NEBO CLEN"+"    "
6350 GOSUB 10000                :REM PRECTI A OTESTUJ ODPOVED
6440 PRINT&CR+1,0;SPC(31)       :REM VYNECH RADEK
6445 CR=CR+2
6447 IF FNM(I,3) <> 0 THEN 6450 :REM NEJSOU NAPSANY 3 VETY
6448 CR=CR-6                    :REM NAPSANY 3 VETY
6449 PRINT&CR,0;SPC(32):PRINT&CR+2,0;SPC(32):PRINT&CR+4,0;SPC(32);
6450 NEXT I
6455 WAIT(10)
6460 RETURN
7000 REM
7001 REM
7002 REM *** TVOR ZAPORNE ODPOVEDI ***
7003 REM -----------------------------
7004 REM
7010 CLS
7020 REM --- PIS POKYNY ---
7030 PRINT&1,1;"            v   '    v       "
7040 PRINT&2,1;"       ODPOVEZ ZAPORNE       "
7100 PRINT&09,0"Dole na obrazovce budou uvedena"
7110 PRINT&11,0"slova, ktera je mozno doplnit "
7120 PRINT&13,0"do odpovedi."
7130 PRINT&15,0"Az se veta napise, stiskni kla-"
7140 PRINT&17,0"vesu s cislici uvedenou u slova,"
7150 PRINT&19,0"ktere ma byt doplneno do vety"
7160 PRINT&21,0"na misto tecek."
7200 GOSUB 4500                 :REM CEKEJ NA TLACITKO
7210 REM
7220 REM --- PRIPRAV OBRAZOVKU ---
7230 FOR I=7 TO 27
7232 PRINT&I,0;SPC(32);
7234 NEXT I
7240 PRINT&24,0;SPC(13);"Slova:"
7245 PRINT""                    :REM VYNECH RADEK
7250 FOR I=1 TO 3
7251 PRINT CHR$(19);I;CHR$(18);"=";MO$(T,I);" ";
7252 NEXT I
7253 PRINT""   :REM NOVY RADEK
7254 FOR I=4 TO 6
7255 PRINT CHR$(19);I;CHR$(18);"=";MO$(T,I);" ";
7256 NEXT I
7300 REM
7310 REM --- PIS VETY A CTI SLOVA ---
7315 CR=12
7320 FOR I=1 TO PO(T)
7330 PRINT&CR,0;V3$(I)          :REM OTAZKA
7332 PRINT&CR+1,0;SPC(31)       :REM VYNECH RADEK
7335 CR=CR+2
7340 H6$="          "+"VYBER SLOVO"+"          "
7350 GOSUB 10000                :REM PRECTI A OTESTUJ ODPOVED
7440 CR=CR-2
7445 PRINT&CR,0;SPC(31)         :REM VYMAZ RADEK
7447 PRINT&CR+2,0;SPC(31)       :REM VYMAZ RADEK
7450 NEXT I
7455 WAIT(10)
7460 RETURN
8000 REM
8001 REM
8002 REM *** VYBER SPRAVNOU ODPOVED ***
8003 REM ------------------------------
8004 REM
8010 CLS
8020 REM --- PIS POKYNY ---
8030 PRINT&1,1;"                 v            "
8040 PRINT&2,1;"            ODPOVEZ            "
8100 PRINT&09,0"Dole na obrazovce budou uvedeny"
8110 PRINT&11,0"vety, kterymi je mozno odpove-"
8120 PRINT&13,0"det."
8130 PRINT&15,0"Az se otazka napise, stiskni "
8140 PRINT&17,0"klavesu s cislici uvedenou u ve-"
8150 PRINT&19,0"ty, kterou chces vybrat jako"
8160 PRINT&21,0"odpoved."
8200 GOSUB 4500                 :REM CEKEJ NA TLACITKO
8210 REM
8220 REM --- PRIPRAV OBRAZOVKU ---
8230 FOR I=7 TO 27
8232 PRINT&I,0;SPC(32);
8234 NEXT I
8240 PRINT&20,0;SPC(13);"Vety:"
8245 PRINT""                    :REM VYNECH RADEK
8251 FOR I=1 TO 4
8252 PRINT CHR$(19);I;CHR$(18);"=";MO$(T,I)
8253 PRINT""                    :REM VYNECH RADEK
8255 NEXT I
8300 REM
8310 REM --- PIS OTAZKY A CTI ODPOVEDI ---
8315 CR=8
8320 FOR I=1 TO PO(T)
8330 PRINT&CR,0;V4$(I)          :REM ODPOVED
8332 PRINT&CR+1,0;SPC(31)       :REM VYNECH RADEK
8335 CR=CR+2
8340 H6$="         "+"VYBER ODPOVED"+"         "
8350 GOSUB 10000                :REM PRECTI A OTESTUJ ODPOVED
8440 CR=CR-2
8445 PRINT&CR,0;SPC(31)         :REM VYMAZ RADEK
8447 PRINT&CR+2,0;SPC(31)       :REM VYMAZ RADEK
8450 NEXT I
8455 WAIT(10)
8460 RETURN
9000 REM
9001 REM
9002 REM *** DOPLN PISMENA ***
9003 REM ---------------------
9004 REM
9010 CLS
9020 REM --- PIS POKYNY ---
9030 PRINT&1,1;"         v          '  v     "
9040 PRINT&2,1;"     NAPIS SLOVO SPRAVNE     "
9100 PRINT&09,0"Na obrazovce se objevi slovo"
9110 PRINT&11,0"s vynechanymi pismeny. Tvym"
9120 PRINT&13,0"ukolem je napsat slovo spravne."
9130 PRINT&15,0"Je nutne ve slovech rozlisovat"
9140 PRINT&17,0"mala a velka pismena."
9150 PRINT&19,0"Po napsani slova stiskni klave-"
9160 PRINT&21,0"su CR."
9200 GOSUB 4500                 :REM CEKEJ NA TLACITKO
9210 REM
9220 REM --- PRIPRAV OBRAZOVKU ---
9230 FOR I=7 TO 27
9232 PRINT&I,0;SPC(32);
9234 NEXT I
9240 PRINT&7,8"Dopln z/tz, s/3"
9300 REM
9305 REM --- PIS SLOVA A CTI ODPOVEDI ---
9310 FOR I=1 TO PO(T)
9315 FOR J=18 TO 31
9317 PRINT&J,0;SPC(31);
9318 NEXT J
9320 PRINT&20,12;MO$(T,I)       :REM NEUPLNE SLOVO
9330 PRINT&28,5;                :REM NASTAV KURZOR
9340 INPUT"SLOVO";O$
9345 PRINT&20,12;SPC(18);
9350 PRINT&20,12;CHR$(19);O$    :REM PIS ODPOVED
9360 FOR J=28 TO 31
9362 PRINT&J,0;SPC(31);
9364 NEXT J
9370 IF O$<>SO$(T,I) THEN 9500  :REM CHYBA
9380 PRINT&31,0;SPC(12);H1$;SPC(12)
9390 WAIT(40)
9395 PRINT&31,0;SPC(31);
9400 NEXT I
9455 WAIT(10)
9460 RETURN
9500 REM
9505 REM --- CHYBA ---
9510 PRINT&31,0;SPC(13);H2$;SPC(13)
9512 PRINT CHR$(7);
9514 WAIT(30)
9530 PC(T,I)=PC(T,I)+1
9590 IF PC(T,I)<=MP THEN 9315   :REM DALSI POKUS
9600 REM 
9605 REM --- PRILIS MNOHO CHYB ---
9610 PRINT&31,0;SPC(7);H3$;SPC(7)
9615 O$=SO$(T,I)
9620 WAIT(30)
9630 PRINT&31,0;SPC(8);H4$;SPC(8)
9650 PRINT&20,12;CHR$(19);O$
9670 GOTO 9390
9999 RETURN
10000 REM
10001 REM
10002 REM *** CTI A TESTUJ ODPOVED ***
10003 REM ----------------------------
10004 REM
10010 K=II(T,I):LL=D(T,I):CS=K  :REM PARAMETRY
10020 PRINT&CR,0;V$(T,I)
10030 PRINT&31,0;H6$;
10040 O$=INKEY$
10050 IF O$="" THEN 10040
10060 IF (O$<"1") THEN 10400    :REM MIMO ROZSAH
10065 IF O$>(CHR$(PO(T)+48)) THEN 10400  :REM MIMO ROZSAH
10070 L=ASC(O$)-ASC("0")        :REM CISLO ODPOVEDI
10080 O$=MO$(T,L)               :REM ODPOVED
10090 IF K=0 THEN GOSUB 4800    :REM ZACATEK VETY
10100 PRINT&CR,K;CHR$(19);O$    :REM DOPLN ODPOVED
10110 IF MO$(T,L)<>SO$(T,I) THEN 10200
10120 PRINT&31,0;SPC(12);H1$;SPC(12)
10130 WAIT(40)
10140 RETURN
10200 REM
10205 REM --- CHYBA ---
10210 PRINT&31,0;SPC(13);H2$;SPC(13)
10220 WAIT(30)
10240 GOSUB 4700                :REM ZABLIKEJ
10280 PC(T,I)=PC(T,I)+1
10290 IF PC(T,I)<=MP THEN 10030 :REM DALSI POKUS
10300 REM 
10305 REM --- PRILIS MNOHO CHYB ---
10310 PRINT&31,0;SPC(7);H3$;SPC(7)
10315 O$=SO$(T,I)
10317 IF K=0 THEN GOSUB 4800    :REM ZACATEK VETY
10320 WAIT(30)
10330 PRINT&31,0;SPC(8);H4$;SPC(8)
10350 PRINT&CR,K;CHR$(19);O$
10360 GOTO 10130
10400 REM 
10405 REM --- ODPOVED MIMO ROZSAH ---
10410 PRINT&30,0;H5$
10420 PRINT&31,0;SPC(11);"CISLA 1-";CHR$(19);CHR$(PO(T)+48);CHR$(18);SPC(10)
10430 WAIT(40)
10450 PRINT&31,0;SPC(31);&30,0SPC(30);
10460 GOTO 10030
11000 REM
11001 REM
11002 REM *** VYPIS VYSLEDKY ***
11003 REM ----------------------
11004 REM
11010 CLS
11015 REM --- SPOCITEJ CELKOVE VYSLEDKY ---
11020 FOR T=1 TO PT
11025 FOR I=1 TO PO(T)
11030 J=PC(T,I)+1
11035 CH(T,J)=CH(T,J)+1
11037 CH(0,J)=CH(0,J)+1
11040 NEXT I
11045 NEXT T
11050 FOR T=1 TO PT
11055 FOR I=1 TO 3
11060 CH$(T,I)=STR$(CH(T,I))
11065 CH$(T,I)=" "+CH$(T,I)+" "
11070 NEXT I
11075 NEXT T
11080 FOR I=1 TO 3
11082 CH$(0,I)=STR$(CH(0,I))
11083 CH(0,0)=CH(0,0)+CH(0,I)
11084 CH$(0,I)=" "+CH$(0,I)+" "
11090 NEXT I
11100 REM
11110 REM --- PIS VYSLEDKY NA OBRAZOVKU ---
11120 PRINT&0,08"      '  '      "
11130 PRINT&1,08"CELKOVE VYSLEDKY"
11150 PRINT"Datum: ";DA$
11160 PRINT"Jmeno: ";JM$
11170 PRINT"Trida: ";TR$
11190 PRINT" "
11200 PRINT"    TEMA";SPC(14);" A  B  C "
11220 PRINT"-------------------------------"
11225 PRINT"   v  '   '   "
11230 PRINT"Tvoreni otazek";SPC(8);CH$(1,1);CH$(1,2);CH$(1,3)
11235 PRINT"   
11240 PRINT"Doplnovani clenu";SPC(6);CH$(2,1);CH$(2,2);CH$(2,3)
11245 PRINT" '    '      v  "
11250 PRINT"Zaporne odpovedi";SPC(6);CH$(3,1);CH$(3,2);CH$(3,3)
11255 PRINT"    v   "
11260 PRINT"Opovedi";SPC(14);CH$(4,1);CH$(4,2);CH$(4,3)
11265 PRINT" "
11270 PRINT"Pravopis z/tz, s/3";SPC(4);CH$(5,1);CH$(5,2);CH$(5,3)
11280 PRINT"-------------------------------"
11285 PRINT" "
11290 PRINT"CELKEM";SPC(16);CH$(0,1);CH$(0,2);CH$(0,3)
11295 PRINT" "
11300 PRINT"A= pocet otazek zodpovezenych"
11305 PRINT "   na poprve"
11310 PRINT"B= pocet otazek zodpovezenych"
11315 PRINT"   na podruhe"
11320 PRINT"C= pocet nezodpovezenych otazek"
11325 PRINT&30,0"T= VYSLEDKY NA TISKARNU"
11330 PRINT&31,0"JINAK= KONEC PROGRAMU";
11400 O$=INKEY$
11405 IF O$="" THEN 11400
11410 IF O$<>"W" THEN RETURN
11415 GOSUB 11500               :REM VYSLEDKY NA TISKARNU
11420 GOTO 11325
11500 REM
11501 REM --- PIS VYSLEDKY NA TISKARNU ---
11505 PRINT&30,6"VYSLEDKY NA TISKARNU";
11506 PRINT&31,013"CEKEJ.";
11520 LPRINT"      '  '      "
11530 LPRINT"CELKOVE VYSLEDKY"
11540 LPRINT" "
11545 LPRINT"Nemecky jazyk, 1.-5. lekce"
11546 LPRINT" "
11550 LPRINT"Datum: ";DA$;"    Trida: ";TR$
11560 LPRINT"Jmeno: ";JM$
11590 LPRINT" "
11600 LPRINT;"    TEMA";SPC(14);" A  B  C "
11620 LPRINT"-------------------------------"
11625 LPRINT"   v  '   '   "
11630 LPRINT"Tvoreni otazek";SPC(8);CH$(1,1);CH$(1,2);CH$(1,3)
11635 LPRINT"    v  ' ' v   o"
11640 LPRINT"Doplnovani clenu";SPC(6);CH$(2,1);CH$(2,2);CH$(2,3)
11645 LPRINT" '    '      v  "
11650 LPRINT"Zaporne odpovedi";SPC(6);CH$(3,1);CH$(3,2);CH$(3,3)
11655 LPRINT"     v  "
11660 LPRINT"Odpovedi";SPC(14);CH$(4,1);CH$(4,2);CH$(4,3)
11665 LPRINT" "
11670 LPRINT"Pravopis z/tz, s/3";SPC(4);CH$(5,1);CH$(5,2);CH$(5,3)
11680 LPRINT"-------------------------------"
11685 LPRINT" "
11690 LPRINT"CELKEM";SPC(16);CH$(0,1);CH$(0,2);CH$(0,3)
11695 LPRINT" "
11700 LPRINT"A= pocet otazek zOdpovezenych"
11705 LPRINT"   na poprve"
11710 LPRINT"B= pocet otazek zodpovezenych"
11715 LPRINT"   na podruhe"
11720 LPRINT"C= pocet nezodpovezenych otazek"
11999 RETURN
12000 REM
12001 REM
12002 REM
12003 REM
12004 REM
12005 REM
12006 REM
12007 REM
12008 REM
12009 REM
12010 REM
20000 REM
20001 REM
20002 REM *** SOUBOR DAT ***
20003 REM ------------------
20004 REM
20005 REM
20006 REM
20007 REM
20008 REM
20009 REM
20010 REM --- TVORENI OTAZEK ---
20011 REM
20012 REM
20013 REM
20014 REM
20015 REM
20016 REM
20017 REM
20018 REM
20019 REM
20020 DATA "wie","wer","was","wo "    :REM MOZNA ZAJMENA
20030 DATA "wer","wo ","was","wie"    :REM SPRAVNA ZAJMENA
20040 DATA "Das ist Katrin."
20045 DATA "... ist das ?",0,3
20050 DATA "Katrin lebt in Berlin."
20055 DATA "... lebt Katrin ?",0,3
20060 DATA "Sie schreibt."
20065 DATA "... macht sie ?",0,3
20070 DATA "Sie schreibt richtig."
20075 DATA "... schreibt sie ?",0,3
20100 REM
20101 REM --- DOPLNOVANI CLENU A ZAJMEN ---
20110 DATA "der ","ein ","er  " :REM MOZNE CLENY
20115 DATA "die ","eine","sie "
20120 DATA "das ","ein ","es  "
20125 DATA "ein ","das ","es  " :REM SPRAVNE CLENY
20130 DATA "ein ","der ","er  ","eine","die ","sie "
20135 DATA "Hier ist .... Kind.",9,4
20140 DATA "Was macht .... Kind ?",10,4
20145 DATA ".... badet.",0,4
20150 DATA "Das ist .... Ball.",8,4
20152 DATA "Wie ist .... Ball ?",8,4
20155 DATA ".... ist gelb.",0,4
20160 DATA "Dort ist .... Frau.",9,4
20165 DATA "Was macht .... Frau ?",10,4
20170 DATA ".... tanzt.",0,4
20200 REM
20201 REM --- ZAPORNE ODPOVEDI ---
20205 DATA "gut   ","falsch","sauber"     :REM MOZNA SLOVA
20210 DATA "wei3  ","rechts","dort  "
20215 DATA "falsch","gut   ","rechts"     :REM SPRAVNA SLOVA
20220 DATA "dort  ","sauber","wei3  "
20225 DATA "Schreibt Thomas richtig ?"
20230 DATA "Nein, Thomas schreibt ...... .",22,6
20235 DATA "Liest das Kind schlecht ?"
20240 DATA "Nein, es liest ...... .",15,6
20245 DATA "Liegt das Buch links ?"
20250 DATA "Nein, das Buch liegt ...... .",21,6
20255 DATA "Ist Barbara hier ?"
20260 DATA "Nein, sie ist ...... .",14,6
20265 DATA "Ist das Fenster schmutzig ?"
20270 DATA "Nein, das Fenster ist ...... .",22,6
20275 DATA "Ist die Katze schwarz ?"
20280 DATA "Nein, die Katze ist ...... .",20,6
20300 REM
20301 REM --- VYBER ODPOVED ---
20305 REM MOZNE ODPOVEDI
20310 DATA "Dort sitzt eine Katze.     "
20315 DATA "Nein, sie ist nicht sauber."
20320 DATA "Hier ist ein Bild.         "
20325 DATA "Sie ist wei3.              "
20330 REM SPRAVNE ODPOVEDI
20335 DATA "Hier ist ein Bild.         "
20340 DATA "Dort sitzt eine Katze.     "
20345 DATA "Sie ist wei3.              "
20350 DATA "Nein, sie ist nicht sauber."
20355 REM OTAZKY
20360 DATA "Was ist hier ?"
20362 DATA "...........................",0,27
20365 DATA "Wer sitzt dort ?"
20367 DATA "...........................",0,27
20370 DATA "Wie ist die Katze ?"
20372 DATA "...........................",0,27
20375 DATA "Ist sie sauber ?"
20377 DATA "...........................",0,27
20400 REM
20401 REM --- DOPLNOVANI PISMEN ---
20405 DATA "si...t","sitzt"
20410 DATA "je...t","jetzt"
20415 DATA "flei...ig","flei3ig"
20420 DATA "schwar...","schwarz"
20425 DATA "Su...i","Susi"
20430 DATA "link...","links"
20435 DATA "wei...","wei3"
20440 DATA "schmu...ig","schmutzig"
20445 DATA "tan...t","tanzt"