15 REM ** KARTEZSKA STRELNICE **
25 REM AUTOR: OTA ZAHORA
30 REM VERZE 2, LEDEN 1987
100 REM
109 REM
110 REM *** HLAVNI PROGRAM ***
140 REM *** INICIALIZACE ***
141 REM
190 POKE 20,1
195 POKE 19,31
200 CLEAR 1000
210 CLS
220 GOSUB 1000  :REM IMPLIC.HOD
230 GOSUB 2000  :REM TITUL.OBR.
240 GOSUB 3000  :REM PARAMETRY
260 POKE10,0:POKE9,0:POKE8,0
290 REM
298 REM *** STRELBA ***
299 REM
300 CLS
301 GOSUB 4000  :REM KRESLI OSY
310 ON RG GOSUB 5000,6000,7000  :REM GENERUJ SOURADNICE
314 LET PP(PB)=0
315 IF X=128 OR Y=128 THEN 310
316 IF RG<>1 THEN 320
317 PB=PB+1
318 VB(1,PB)=X
319 VB(2,PB)=Y
320 GOSUB 8000  :REM KRESLI BOD
330 GOSUB 5000  :REM CTI SOURAD
340 IF X=128 OR Y=128 THEN 500  :REM PRILIS MNOHO CHYB
350 IF VB(1,PB)=X AND VB(2,PB)=Y THEN 390   :REM SOUHLASI
360 REM * NESOUHLAS SOURADNIC *
370 GOSUB 9000  :REM OSETRI CHYBU
375 IF X=128 OR Y=128 THEN 500  :REM PRILIS MNOHO CHYB
380 GOTO 330
390 REM * SOUHLAS SOURADNIC *
400 GOSUB 9600  :REM ZASAH
500 IF PB<CB THEN 300           :REM KONEC ?
510 REM
520 REM *** VYPIS VYSLEDKY ***
540 GOSUB 11000
550 REM
560 REM *** KONEC PROGRAMU ***
900 POKE 20,2
910 END:RUN
995 REM
996 REM
997 REM *** INICIALIZACE ***
998 REM --------------------
999 REM
1000 REM
1010 RESTORE
1020 LET CB=10                  :REM MAX.POCET GENER. BODU
1030 LET PB=0                   :REM POCET DOSUD VYGEN.BODU
1040 DIM VB(2,30)               :REM VYGENEROVANE BODY
1050 DIM PP(30)                 :REM PP(I)=POC.CHYB PRO I.BOD
1060 LET CP=5                   :REM MAX.POKUSU NA 1 BOD
1070 DIM ZB(2,30,10)            :REM HADANE SOURADNICE
1080 DIM CI$(14)  :REM POPIS OS
1090 FOR I=1 TO 7
1100 CI$(I)=" "+CHR$(7-I+48)
1105 CI$(I+7)="-"+CHR$(I+48)
1110 NEXT I
1120 DIM OX$(32)  :REM OSA X
1130 FOR I=3 TO 13 STEP 2
1140 OX$(I)="-":OX$(I+14)="+"
1150 NEXT I
1160 FOR I=4 TO 16 STEP 2
1170 J=(I-4)/2
1180 OX$(I)=CHR$(48+6-J):OX$(I+14)=CHR$(48+1+J)
1190 NEXT I
1200 OX$(15)=" "
1225 LET DM=-6:HM=6             :REM MEZE SOURADNIC
1230 LET A=HM-DM+1:B=DM
1240 LET RG=3
1250 DIM KX(14),KY(14)          :REM TAB.KONVERZI SOURADNIC
1260 FOR I=1 TO 13
1270 KX(I)=2*I+2:KY(I)=28-2*I
1290 NEXT I
1300 KX(0)=4:KX(14)=28
1310 KY(0)=26:KY(14)=2
1335 LET KX(9)=20 :REM X=2
1500 LET X=0: Y=0
1510 LET I=0: J=0
1590 DIM CH(2,5)                :REM CELKOVE VYSLEDKY
1600 GOSUB 2700                 :REM OSOBNI UDAJE
1890 WAIT(40)
1900 RETURN
1995 REM
1996 REM
1997 REM *** POPIS CINNOSTI ***
1998 REM ----------------------
1999 REM
2000 CLS
2022 PRINT&4,3"POPIS CINNOSTI PROGRAMU"
2023 PRINT&5,3"-----------------------"
2030 PRINT&7,2"Program zobrazuje body     "
2040 PRINT&8,2"(=cile) v kartezske sousta-"
2050 PRINT&9,2"ve souradnic o rozmerech "
2060 PRINT&10,2"<-6,6>x<-6,6>. Ukolem je"
2070 PRINT&11,2"urcit jejich souradnice."
2080 PRINT&12,2"Zadana souradnice se odesi-"
2085 PRINT&13,2"la tlacitkem CR."
2090 PRINT&14,2"Maximalni pocet pokusu na 1"
2100 PRINT&15,2"bod lze zadat az do vyse 5,"
2110 PRINT&16,2"jinak je to 5 pokusu."
2115 PRINT&17,2"Pocet bodu lze zadat az do"
2120 PRINT&18,2"poctu 30, jinak je to 10"
2130 PRINT&19,2"bodu."
2140 PRINT&20,2"Chybne zadane souradnice se"
2150 PRINT&21,2"vypisuji vlevo nahore."
2160 PRINT&22,2"Na zaver se vypise celkove"
2170 PRINT&23,2"hodnoceni."
2190 PRINT&26,2"Az budes chtit pokracovat, "
2200 PRINT&27,2"stiskni lib. cernou klavesu"
2300 IF INKEY$="" THEN 2300
2310 RETURN
2700 REM
2702 REM *** OSOBNI UDAJE ***
2704 REM
2705 CLS
2709 PRINT&4,3;"0"
2710 PRINT&4,3;"Jsem tvuj pomocnik v uceni"
2715 PRINT&6,6;"mikropocitac IQ 151"
2720 PRINT&9,0;"Jak se jmenujes ty ?"
2725 PRINT&11,0;"(po napsani zmackni vzdy CR)"
2727 POKE 17,1
2730 CR=13:CS=0:PRINT&CR,CS     :REM PARAMETRY
2735 INPUT JM$                  :REM CTI JMENO
2737 POKE 17,0
2740 PRINT&CR,CS;" "
2745 PRINT&16,0;"Z ktere jsi tridy ?"
2747 POKE 17,1
2750 CR=18:CS=0:PRINT&CR,CS     :REM PARAMETRY
2755 INPUT TR$                  :REM CTI TRIDU
2757 POKE 17,0
2760 PRINT&CR,CS;" "
2765 PRINT&21,0;"Jake je dnesni datum ?"
2767 POKE 17,1
2770 CR=23:CS=0:PRINT&CR,CS     :REM PARAMETRY
2775 INPUT DA$                  :REM CTI DATUM
2777 POKE 17,0
2780 PRINT&CR,CS;" "
2785 PRINT&27,0;"Dekuji Ti, a vzhuru do prace !"
2995 REM
2996 REM
2997 REM *** POKYNY ***
2998 REM --------------
2999 RETURN
3000 CLS
3020 PRINT&4,13"POKYNY"
3030 PRINT&5,13"------"
3040 PRINT&6,2"Nasledujicimi pokyny lze"
3050 PRINT&7,2"ridit cinnost programu."
3060 PRINT&8,2"Pokyn se zadava stisknutim"
3070 PRINT&9,2"prislusneho tlacitka."
3080 PRINT&10,2"Nyni lze zadat pouze pokyny"
3090 PRINT&11,2"N,D,K,C,P. Pokyny V a E lze"
3100 PRINT&12,2"zadat misto souradnice X"
3110 PRINT&13,2"pri 'sestrelovani' cilu."
3115 PRINT&14,2"Stisknutim jineho cerne-"
3116 PRINT&15,2"ho tlacitka se program"
3117 PRINT&16,2"pousti dale."
3120 PRINT&18,2"Zpusob zadavani cilu:"
3130 PRINT&19,3"N...nahodne generovani"
3140 PRINT&20,3"D...cteni ze souboru DATA"
3150 PRINT&21,3"K...cteni z klavesnice"
3160 PRINT&22,2"Pocet cilu a pokusu:"
3170 PRINT&23,3"C...jiny pocet nez 10 cilu"
3175 PRINT&24,3"P...jiny pocet nez 5pokusu"
3180 PRINT&25,2"Dalsi pokyny:"
3190 PRINT&26,3"V...prubezne vysledky"
3200 PRINT&27,3"E...ukonci ihned program"
3250 GOSUB 3500    :REM CTI POKYN
3260 RETURN
3495 REM
3496 REM
3497 REM *** CTENI POKYNU ***
3498 REM --------------------
3499 REM
3500 PRINT&30,0"ZADEJ POKYN";SPC(19)
3505 C$=INKEY$
3510 IF C$="" THEN 3505
3515 IF C$="N" THEN 3800        :REM NAHODNE GENEROVANI
3520 IF C$="D" THEN 3820        :REM CILE ZE SOUBORU
3525 IF C$="K" THEN 3840        :REM CILE Z KLAVESNICE
3530 IF C$="E" THEN 3860             :REM KONEC PROGRAMU
3535 IF C$="C" THEN 3700        :REM POCET CILU
3537 IF C$="P" THEN 3900        :REM POCET POKUSU
3540 PRINT&30,0;SPC(30)
3550 RETURN
3699 REM
3700 REM ** CTI POCET CILU **
3701 REM
3705 PRINT&30,0;SPC(30)
3710 PRINT&30,0
3711 LET C$=""
3715 INPUT "ZADEJ POCET CILU";C$
3720 IF LEN(C$)>2 THEN 3770
3725 IF LEFT$(C$,1)<"0" OR LEFT$(C$,1)>"9" THEN 3770
3730 IF RIGHT$(C$,1)<"0" OR RIGHT$(C$,1)>"9" THEN 3770
3735 P=VAL(C$)
3740 IF P<0 OR P>30 THEN 3770
3760 CB=P
3765 GOTO 3500
3770 PRINT&30,0"NUTNO ZADAT CISLO Z <1,30>";SPC(2);
3775 WAIT(25)
3780 GOTO 3705
3799 REM
3800 REM ** NAHODNE GENEROVANI **
3801 REM
3805 RG=3
3806 PRINT&30,0"NAHODNE CILE";SPC(18)
3807 WAIT(25)
3810 GOTO 3500
3820 REM ** CTENI ZE SOUBORU **
3821 REM
3825 RG=2
3826 PRINT&30,0"CILE ZE SOUBORU DATA";SPC(10)
3827 WAIT(25)
3830 GOTO 3500
3840 REM ** CTENI Z KLAVESNICE **
3841 REM
3845 RG=1
3846 PRINT&30,0"CILE Z KLAVESNICE";SPC(13)
3847 WAIT(25)
3850 GOTO 3500
3859 REM
3860 REM ** UKONCENI PROGRAMU **
3861 REM
3863 PRINT&30,0"KONEC PROGRAMU";SPC(16)
3864 WAIT(25)
3865 POKE 20,2
3866 CLS
3870 END
3875 RUN
3899 REM
3900 REM ** CTI POCET POKUSU **
3901 REM
3905 PRINT&30,0;SPC(30)
3910 PRINT&30,0
3911 LET C$=""
3915 INPUT "ZADEJ MAX.POCET POKUSU";C$
3920 IF LEN(C$)>2 THEN 3945
3925 IF LEFT$(C$,1)<"0" OR LEFT$(C$,1)>"9" THEN 3945
3930 IF RIGHT$(C$,1)<"0" OR RIGHT$(C$,1)>"9" THEN 3945
3935 P=VAL(C$)
3940 IF P>0 AND P<6 THEN 3960
3945 PRINT&30,0"NUTNO ZADAT CISLO Z <1,5>";SPC(3);
3950 WAIT(25)
3955 GOTO 3905
3960 LET CP=P
3965 GOTO 3500
3995 REM
3996 REM
3997 REM *** NAKRESLI OSY ***
3998 REM --------------------
3999 REM
4000 REM OBRAZOVKA SE NEMAZE
4020 FOR I=3 TO 25 STEP 2
4030 PRINT&I,16;CHR$(15);"T"
4040 NEXT I
4050 FOR I=2 TO 26 STEP 2
4060 PRINT&I,15;CI$(I/2)
4070 NEXT I
4080 PRINT&0,16"y"
4110 PRINT&14,0"   -6-5-4-3-2-1 0+1+2+3+4+5+6  x"
4120 RETURN
4495 REM
4496 REM
4497 REM *** ZAHLAVI SEZNAMU NEUSPECHU ***
4498 REM ---------------------------------
4500 PRINT&1,0" x y"
4510 PRINT&2,0"----"
4520 RETURN
4995 REM
4996 REM
4997 REM *** CTI SOURADNICE ***
4998 REM ----------------------
4999 REM
5000 LET X$="":X=128:Y$="":Y=128
5004 REM
5005 REM * CTI X *
5006 REM .........
5009 LET I=0
5010 PRINT&30,0;SPC(30)
5020 PRINT&30,0
5030 PRINT"ZADEJ X:";:GOSUB15000:X$=V$
5035 IF LEN(X$)=0 THEN 5830     :REM PRAZDNE X
5050 IF LEN(X$)>2 THEN 5750     :REM PRILIS DLOUHE
5060 IF LEN(X$)=2 THEN 5130
5070 REM * ZADAN JEDEN ZNAK *
5080 IF (X$>="A" AND X$<="Z") THEN 5800   :REM PISMENO
5090 IF X$<"0" OR X$>"9" THEN 5450        :REM NENI CISLO
5100 X=VAL(X$)
5110 IF X>HM OR X<DM THEN 5500  :REM X MIMO ROZSAH
5120 GOTO 5190
5130 REM * ZADANY 2 ZNAKY *
5140 IF LEFT$(X$,1)="-" OR LEFT$(X$,1)="+" THEN 5160
5145 IF LEFT$(X$,1)=" " THEN 5160
5150 IF LEFT$(X$,1)<"0" OR LEFT$(X$,1)>"9" THEN 5450
5160 IF RIGHT$(X$,1)<"0" OR RIGHT$(X$,1)>"9" THEN 5450
5170 GOTO 5100      :REM CISLO
5190 X$=""
5204 REM
5205 REM * CTI Y *
5206 REM .........
5210 PRINT&30,0;SPC(30)
5220 PRINT&30,0
5230 PRINT"ZADEJ Y:";:GOSUB15000:Y$=V$
5235 IF LEN(Y$)=0 THEN 5830     :REM PRAZDNE Y
5250 IF LEN(Y$)>2 THEN 5750     :REM PRILIS DLOUHE
5260 IF LEN(Y$)=2 THEN 5330
5270 REM * ZADAN JEDEN ZNAK *
5280 IF (Y$>="A" AND Y$<="Z") THEN 5450   :REM PISMENO
5290 IF Y$<"0" OR Y$>"9" THEN 5450        :REM NENI CISLO
5300 Y=VAL(Y$)
5310 IF Y>HM OR Y<DM THEN 5500        :REM Y MIMO ROZSAH
5320 GOTO 5390
5330 REM * ZADANY 2 ZNAKY *
5340 IF LEFT$(Y$,1)="-" OR LEFT$(Y$,1)="+" THEN 5360
5345 IF LEFT$(Y$,1)=" " THEN 5360
5350 IF LEFT$(Y$,1)<"0" OR LEFT$(Y$,1)>"9" THEN 5450
5360 IF RIGHT$(Y$,1)<"0" OR RIGHT$(Y$,1)>"9" THEN 5450
5370 GOTO 5300     :REM CISLO
5390 Y$=""
5397 REM
5398 REM * SOURADNICE PRECTENY *
5399 REM .......................
5400 PRINT&30,0;SPC(30)
5410 RETURN
5447 REM
5448 REM ** NEKTERA SOURADNICE NENI CISLO **
5449 REM ...................................
5450 PRINT&30,0"ZADANA SOURADNICE NENI CISLO"
5460 WAIT(40)
5470 IF LEN(X$)<>0 THEN 5000    :REM CTI ZNOVU X
5480 GOTO 5210                  :REM CTI ZNOVU Y
5497 REM
5498 REM ** NEKTERA SOURADNICE MIMO ROZSAH **
5499 REM ....................................
5500 PRINT&30,0"SOURAD. MIMO INTERVAL <-6,6>"
5505 WAIT(40)
5510 REM * ZAPAMATUJ SI SOURADNICE *
5520 PP(PB)=PP(PB)+1
5530 ZB(1,PB,PP(PB))=X
5540 ZB(2,PB,PP(PB))=Y
5550 REM * VYPIS SOURADNICE *
5560 I=PP(PB)+2
5570 IF I=3 THEN GOSUB 4500     :REM NAPIS ZAHLAVI
5580 POKE 17,1
5581 J=0
5582 IF X$="" THEN X$=STR$(X)
5583 IF LEN(X$)=1 THEN X$=" "+X$
5584 IF LEN(Y$)=1 THEN Y$=" "+Y$
5590 PRINT&I,J;X$;Y$
5600 POKE 17,0
5610 IF PP(PB)>=CP THEN 5700    :REM PRILIS MNOHO CHYB
5620 GOTO 5000                  :REM CTI DALSI X,Y
5697 REM
5698 REM ** PRILIS MNOHO CHYB **
5699 REM .......................
5700 PRINT&30,0"PRILIS MNOHO CHYB";SPC(13)
5710 WAIT(30)
5720 X=128: Y=128
5730 GOTO 5400
5750 REM ** NEKT.SOURAD.PRILIS DLOUHA **
5755 PRINT&30,0"PRILIS DLOUHY RETEZEC"
5760 WAIT(40)
5765 IF LEN(X$)<>0 THEN 5000    :REM CTI ZNOVU X
5770 GOTO 5210   :REM CTI ZNOVU Y
5797 REM
5798 REM ** POKYN ? **
5799 REM .............
5800 REM MEZIVYSLEDKY
5820 GOSUB 11000  :REM VYSLEDKY
5830 CLS
5840 GOSUB 4000   :REM OSY
5850 GOSUB 8000   :REM BOD
5860 IF PP(PB)=0 THEN 5000      :REM ZATIM BEZ CHYBY
5870 I=PP(PB)+2
5880 IF I=3 THEN GOSUB 4500     :REM ZAHLAVI SEZNAMU CHYB
5890 POKE 17,1
5900 FOR K=1 TO PP(PB)
5910 X$=STR$(ZB(1,PB,K))
5915 Y$=STR$(ZB(2,PB,K))
5920 IF LEN(X$)=1 THEN X$=" "+X$
5925 IF LEN(Y$)=1 THEN Y$=" "+Y$
5930 PRINT&I,0;X$;Y$
5935 I=I+1
5940 NEXT K
5950 POKE 17,0
5955 GOTO 5000    :REM CTI X
5959 REM * UKONCI PROGRAM *
5960 POKE 20,2
5961 PRINT&30,0"KONEC PROGRAMU";SPC(16)
5962 WAIT(15)
5963 POKE 20,2
5964 CLS
5965 END
5966 RUN
5995 REM
5996 REM
5997 REM *** CTENI SOURADNIC ZE SOUBORU DATA ***
5998 REM ---------------------------------------
5999 REM
6000 LET PB=PB+1
6010 READ X,Y
6011 LET VB(1,PB)=X
6012 LET VB(2,PB)=Y
6020 RETURN
6099 REM
6100 REM SOUBOR SOURADNIC
6110 DATA 1,3,3,1,-5,2,-1,-1,0,5
6120 DATA 1,-3,3,1,4,6,-4,-5,-6,-2
6130 DATA 0,0,5,0,-2,1,,2,0,2,-2
6140 DATA 3,3,2,1,-4,0,-2,-1,4,6
6150 DATA 6,-4,6,6,6,-1,-1,-1,2,-5
6160 DATA -6,-5,2,0,0,-1,1,3,4,-6 
6995 REM
6996 REM
6997 REM *** GENEROVANI NAHODNYCH SOURADNIC ***
6998 REM --------------------------------------
6999 REM
7000 LET PB=PB+1
7010 LET X=INT(A*RND(0))+B
7020 LET Y=INT(A*RND(0))+B
7030 LET VB(1,PB)=X
7040 LET VB(2,PB)=Y
7100 RETURN
7995 REM
7996 REM
7997 REM *** NAKRESLI BOD [X,Y] ***
7998 REM --------------------------
7999 REM
8000 LET U=VB(1,PB)  :REM X
8010 LET V=VB(2,PB)  :REM Y
8020 LET I=KY(V+7)
8030 LET J=KX(U+7)
8035 IF U=-1 AND V<0 THEN 8210
8036 IF V=0 AND U<>-1 THEN 8230
8100 PRINT&I,J"@"
8200 RETURN
8209 REM * OSA y POSKOZENA *
8210 V$=STR$(V)
8215 PRINT&I,J"@";V$
8220 RETURN
8229 REM * OSA x POSKOZENA *
8230 PRINT&I,J"@"
8235 FOR K=J+1 TO 28 
8240 PRINT&I,K;OX$(K)
8245 NEXT K
8250 RETURN
8495 REM
8496 REM
8497 REM *** VYMAZ BOD [X,Y] ***
8498 REM -----------------------
8499 REM
8500 IF X=0 OR Y=0 THEN 8600         :REM NEKTERA OSA POSKOZENA
8510 LET I=KY(Y+7)
8520 LET J=KX(X+7)
8530 PRINT&I,J" "
8590 RETURN
8599 REM * NEKTERA OSA POSKOZENA *
8600 GOSUB 4000                 :REM NAKRESLI OSY ZNOVU
8610 GOSUB 8000                 :REM NAKRESLI ZNOVU CIL
8620 RETURN
8995 REM
8996 REM
8997 REM *** VEDLE ***
8998 REM -------------
8999 REM
9000 PRINT&30,0"VEDLE";SPC(23)
9005 PRINT CHR$(7)  :REM BEEP
9010 REM * OZNAC BOD *
9020 LET I=KY(Y+7)
9030 LET J=KX(X+7)
9040 PRINT&I,J"x"
9045 WAIT(50)
9050 REM * ZAPAMATUJ SI SOURADNICE *
9060 PP(PB)=PP(PB)+1
9070 ZB(1,PB,PP(PB))=X
9080 ZB(2,PB,PP(PB))=Y
9090 REM * VYPIS SOURADNICE *
9100 I=PP(PB)+2
9110 IF I=3 THEN GOSUB 4500     :REM NAPIS ZAHLAVI
9120 POKE 17,1
9130 J=0
9140 X$=STR$(X)
9150 Y$=STR$(Y)
9160 IF LEN(X$)=1 THEN X$=" "+X$
9170 IF LEN(Y$)=1 THEN Y$=" "+Y$
9180 PRINT&I,J;X$;Y$
9190 POKE 17,0
9200 GOSUB 8500  :REM VYMAZ BOD
9210 IF PP(PB)<CP THEN 9400     :REM PRILIS MNOHO CHYB ?
9298 REM
9299 REM ** PRILIS MNOHO CHYB **
9300 PRINT&30,0"PRILIS MNOHO CHYB";SPC(13)
9310 WAIT(30)
9320 X=128: Y=128
9400 RETURN
9595 REM
9596 REM
9597 REM *** ZASAH ***
9598 REM -------------
9599 REM
9600 PRINT&30,0"ZASAH";SPC(20)
9620 WAIT(20)
9630 RETURN
10995 REM
10996 REM
10997 REM *** TISKNI VYSLEDKY ***
10998 REM -----------------------
10999 REM
11000 GOSUB 13500  :REM OS.UDAJE
11001 FOR I=0 TO 2:FOR J=0 TO 5
11002 CH(I,J)=0
11003 NEXTJ:NEXT I
11005 LET M=1:N=10:Q=0          :REM 10 BODU NA OBRAZOVKU
11010 IF M>PB THEN 11800        :REM KONEC VYSLEDKU
11020 CLS
11030 PRINT&0,0"ZADANY BOD  POKUSY         CHYB"
11040 IF N>PB THEN Q=N-PB       :REM POCET BODU NEBYL NASOBEK 10
11045 IF N>PB THEN N=PB
11050 LET K=0
11055 IF PB>=CB THEN 11060      :REM CELKOVE VYSLEDKY
11056 IF N>=PB THEN N=N-1       :REM BEZ POSL.BODU
11057 IF N=0 THEN 12600
11060 REM
11061 REM ** TISKNI OBRAZOVKU **
11062 REM ......................
11063 REM
11070 FOR I=M TO N
11080 REM
11081 REM * TISKNI UDAJE O I-TEM BODU *
11100 IF K=0 THEN 11120
11110 PRINT&K,0"-------------------------------"
11120 REM * TISKNI SOURADNICI x *
11121 REM .......................
11130 C$=STR$(I)
11140 IF LEN(C$)=1 THEN C$=" "+C$
11150 PRINT&K+1,0;C$;". x: "
11160 C$=STR$(VB(1,I))
11170 IF LEN(C$)=1 THEN C$=" "+C$
11180 PRINT&K+1,6;C$;" ";CHR$(15);"T"
11190 PRINT&K+1,11;SPC(20)
11200 REM * x CHYBNYCH POKUSU *
11201 REM .....................
11210 IF PP(I)<=0 THEN 11280    :REM ZASAH NA 1. POKUS
11220 FOR J=1 TO PP(I)
11230 C$=STR$(ZB(1,I,J))
11240 IF LEN(C$)=1 THEN C$=" "+C$
11245 P=11+3*(J-1)
11250 PRINT&K+1,P;C$
11260 NEXT J
11270 REM * x USPESNEHO POKUSU *
11271 REM ......................
11280 IF PP(I)>=CP THEN 11330   :REM NEBYL ZASAH
11290 C$=STR$(VB(1,I))
11300 IF LEN(C$)=1 THEN C$=" "+C$
11305 P=11+3*PP(I)
11310 PRINT&K+1,P;C$
11330 C$=STR$(PP(I))
11340 PRINT&K+1,26;CHR$(15);"T"
11350 PRINT&K+1,29;C$
11360 REM * TISKNI SOURADNICI y *
11361 REM .......................
11370 PRINT&K+2,0"    y: "
11380 C$=STR$(VB(2,I))
11390 IF LEN(C$)=1 THEN C$=" "+C$
11400 PRINT&K+2,6;C$;" ";CHR$(15);"T"
11410 PRINT&K+2,11;SPC(20)
11420 REM * y CHYBNYCH POKUSU *
11421 REM .....................
11430 IF PP(I)<=0 THEN 11510    :REM ZASAH NA 1. POKUS
11440 FOR J=1 TO PP(I)
11450 C$=STR$(ZB(2,I,J))
11455 IF C$="128" THEN C$="  "
11460 IF LEN(C$)=1 THEN C$=" "+C$
11475 P=11+3*(J-1)
11480 PRINT&K+2,P;C$
11490 NEXT J
11500 REM * y USPESNEHO POKUSU *
11501 REM ......................
11510 IF PP(I)>=CP THEN 11560   :REM NEBYL ZASAH
11520 C$=STR$(VB(2,I))
11530 IF LEN(C$)=1 THEN C$=" "+C$
11540 P=11+3*PP(I)
11550 PRINT&K+2,P;C$
11560 PRINT&K+2,26;CHR$(15);"T"
11565 LET K=K+3
11600 NEXT I
11610 REM ** KONEC TISKU OBRAZOVKY **
11620 REM
11629 REM
11630 REM ** VYMAZ DOLNI CAST OBRAZOVKY **
11631 REM ................................
11635 REM MA SE VYMAZAT 3*Q RADKU
11640 IF Q=0 THEN 11740         :REM OBRAZOVKA JE CELA
11660 J=30-3*Q                  :REM CISLO RADKU
11670 IF PB<CB THEN J=J-3
11680 PRINT&J,0"-------------------------------"
11685 LET J=J+1
11690 FOR I=J TO 30
11700 PRINT&J,0;SPC(31)
11710 NEXT I
11719 REM
11720 REM ** CEKANI NA DALSI OBRAZOVKU **
11721 REM
11740 PRINT&30,0"DALE=LIBOVOLNE CERNE TLACITKO"
11750 IF INKEY$="" THEN 11750
11760 LET M=M+10
11765 LET N=N+10
11770 GOTO 11010                :REM DALSI OBRAZOVKA
11797 REM
11798 REM ** CELKOVA TABULKA **
11799 REM
11800 CLS
11810 PRINT&0,0"CELKOVE HODNOCENI"
11820 PRINT&3,3"CELKEM";SPC(10);"CILU";SPC(3);"BODU"
11830 PRINT&4,0"------------------------------"
11833 REM CH(0,0)=CELKOVY POCET BODU
11834 REM CH(0,1)=CELKOVA USPESNOST V %
11835 REM CH(1,i)=POCET POKUSU S i CHYBAMI; i=0,...,CP
11836 REM CH(2,i)=POCET BODU ZA POKUSY S i CHYBAMI
11837 N=N-10
11838 IF PB<CB AND N>=PB THEN N=N-1
11840 FOR I=1 TO N
11860 CH(1,PP(I))=CH(1,PP(I))+1
11870 CH(2,PP(I))=CH(2,PP(I))+(CP-PP(I))
11880 CH(0,0)=CH(0,0)+(CP-PP(I))
11900 NEXT I
11905 I=5
11910 PRINT&5,0"primych zasahu"
11911 LET I=I+1
11915 IF CP<=1 THEN 11960
11920 PRINT&I,0"zasahu na 2.pokus"
11921 LET I=I+1
11925 IF CP<=2 THEN 11960
11930 PRINT&I,0"zasahu na 3.pokus"
11931 LET I=I+1
11935 IF CP<=3 THEN 11960
11940 PRINT&I,0"zasahu na 4.pokus"
11941 LET I=I+1
11945 IF CP<=4 THEN 11960
11950 PRINT&I,0"zasahu na 5.pokus"
11951 LET I=I+1
11960 PRINT&I,0"nezasazenych bodu"
11970 PRINT&I+1,0"------------------------------"
11980 FOR J=0 TO CP
11990 C$=STR$(CH(1,J))
12000 IF LEN(C$)=1 THEN C$=" "+C$
12010 PRINT&J+5,20;C$
12020 C$=STR$(CH(2,J))
12030 IF LEN(C$)=1 THEN C$=" "+C$
12040 IF LEN(C$)=2 THEN C$=" "+C$
12050 PRINT&J+5,25;C$
12060 NEXT J
12065 REM
12066 REM ** CELKOVE HODNOCENI **
12067 REM .......................
12070 C$=STR$(N)
12080 IF LEN(C$)=1 THEN C$=" "+C$
12090 PRINT&I+2,20;C$
12100 C$=STR$(CH(0,0))
12110 IF LEN(C$)=1 THEN C$=" "+C$
12120 IF LEN(C$)=2 THEN C$=" "+C$
12130 PRINT&I+2,25;C$
12140 CH(0,1)=INT(100*(CH(0,0)/(CP*N)))
12150 C$=STR$(CH(0,1))
12160 POKE 17,1
12170 PRINT&15,0"uspesnost= ";C$;"%"
12180 POKE 17,0
12190 PRINT&17,0"dosazeno     bodu z     moznych"
12200 C$=STR$(CH(0,0))
12210 PRINT&17,9;C$
12220 C$=STR$(CP*N)
12230 PRINT&17,20;C$
12240 PRINT&23,1"Chces-li vysledky vytisknout"
12250 PRINT&24,1"na tiskarnu, stiskni T."
12260 PRINT&25,1"Chces-li vysledky vytisknout"
12270 PRINT&26,1"na obrazovku, stiskni O."
12280 PRINT&27,1"Jinak stiskni libovolne"
12290 PRINT&28,1"jine cerne tlacitko."
12300 O$=INKEY$
12305 IF O$="" THEN 12300
12310 IF O$="O" THEN 11000
12320 IF O$<>"T" THEN 12500
12330 PRINT&30,0"Vysledky se tisknou, cekej."
12340 GOSUB 14000
12350 PRINT&30,0;SPC(32);
12360 GOTO 12300
12500 REM
12510 REM ** NAVRAT **
12515 CLS
12550 RETURN
12599 REM 
12600 PRINT&2,0"MEZIVYSLEDKY NEJSOU"
12610 GOTO 12240
13500 REM
13501 REM ** OS. UDAJE NA OBRAZ.**
13510 CLS
13520 PRINT&2,6"    '   '   v      "
13530 PRINT&3,6"KARTEZSKA STRELNICE"
13540 PRINT&5,12" '      "
13550 PRINT&6,12"Vysledky"
13560 PRINT&12,1"Datum: ";DA$
13570 PRINT&14,1"Jmeno: ";JM$
13580 PRINT&16,1"Trida: ";TR$
13590 PRINT&29,1"Dale= stiskni libovolnou"
13600 PRINT&30,1"    cernou klavesu.     ";
13630 IF INKEY$="" THEN 13630
13640 RETURN
14000 REM
14001 REM
14002 REM *** TISK VYSLEDKU NA TISKARNU ***
14003 REM ---------------------------------
14004 REM
14005 IF N=0 THEN 14600
14010 LPRINT"    '   '   v      "
14020 LPRINT"KARTEZSKA STRELNICE"
14030 LPRINT"                   "
14040 LPRINT"      '            "
14050 LPRINT"     VYSLEDKY      "
14060 LPRINT" "
14070 LPRINT" "
14080 LPRINT"Datum: ";DA$
14090 LPRINT"Jmeno: ";JM$
14100 LPRINT"Trida: ";TR$
14110 LPRINT" "
14120 LPRINT" "
14130 LPRINT"CELKOVE HODNOCENI"
14135 LPRINT" "
14140 LPRINT"CELKEM";SPC(13);"CILU";SPC(3);"BODU"
14145 LPRINT"------------------------------"
14150 FOR J=0 TO CP-1
14160 C$=STR$(CH(1,J))
14170 IF LEN(C$)=1 THEN C$=" "+C$
14180 D$=STR$(CH(2,J))
14190 IF LEN(D$)=1 THEN D$=" "+D$
14200 IF LEN(D$)=2 THEN D$=" "+D$
14210 LPRINT"zasahu na ";CHR$(J+49);".pokus   ";C$;"   ";D$
14220 NEXT J
14230 C$=STR$(CH(1,CP))
14240 IF LEN(C$)=1 THEN C$=" "+C$
14250 D$=STR$(CH(2,CP))
14260 IF LEN(D$)=1 THEN D$=" "+D$
14270 IF LEN(D$)=2 THEN D$=" "+D$
14280 LPRINT"nezasazenych bodu   ";C$;"   ";D$
14290 LPRINT"------------------------------"
14300 LPRINT" "
14310 C$=STR$(N):D$=STR$(CH(0,0))
14320 IF LEN(C$)=1 THEN C$=" "+C$
14330 IF LEN(D$)=1 THEN D$=" "+D$
14340 IF LEN(D$)=2 THEN D$=" "+D$
14350 LPRINT;SPC(20);C$;"   ";D$
14360 LPRINT" "
14370 C$=STR$(CH(0,1))
14380 LPRINT"uspesnost= ";C$;" %"
14390 LPRINT" "
14400 C$=STR$(CH(0,0)):D$=STR$(CP*N)
14410 LPRINT"dosazeno ";C$;" bodu z ";D$;" moznych"
14500 RETURN
14600 PRINT&30,0"MEZIVYSLEDKY NEJSOU";SPC(11);
14605 WAIT(25)
14610 RETURN
15000 REM INPUT
15005 PRINT&30,12;
15010 INPUTYV
15025 IF ABS(YV)>6THEN15005
15060 PRINT&30,12"                  "
15300 V$=STR$(YV)
15310 RETURN