0 REM azimut
1 REM KOMENIUM n.p.PRAHA
3 REM:871007:
100 POKE20,2
150 CLS:M$="                                "
200 GOSUB 900: GOSUB 700
210 CLS: V=1
220 GOSUB 1000:GOSUB 600
230 CLS: V=2
240 GOSUB 1000:GOSUB 500
250 CLS: V=3
260 GOSUB 1000
270 WAIT(10):GOTO 1350
300 REM mazani
310 PRINT &2,0;M$;&28,0;M$
320 PRINT&4,28;"  "
330 RETURN
400 REM sipky
405 IF V=3 THEN 480
410 IF P<>7 THEN 420
415 PRINT&4,1"M  ";&5,1" \ ";&6,1"  \": RETURN
420 IF P<>6 THEN 430
425 PRINT& 4,1"   ";& 5,1"H--";&6,1"   ": RETURN
430 IF P<>5 THEN 440
435 PRINT&4,1"  /";&5,1" / ";&6,1"M  ": RETURN
440 IF P<>4 THEN 450
445 PRINT&4,1" T ";&5,1" T ";&6,1" H ": RETURN
450 IF P<>3 THEN 460
455 PRINT&4,1"\  ";&5,1" \ ";&6,1"  M": RETURN
460 IF P<>2 THEN 470
465 PRINT&4,1"   ";&5,1"--H";&6,1"   ": RETURN
470 IF P<>1 THEN 480
475 PRINT&4,1"  M";&5,1" / ";&6,1"/  ": RETURN
480 PRINT&4,1" H ";&5,1" T ";&6,1" T ": RETURN
500 REM text 3
510 PRINT: PRINT"*** TRETI SERIE ULOH:"
515 PRINT: PRINT"I v teto serii kruh zustava."
520 PRINT"V levem hornim rohu se objevuje"
525 PRINT"sipka, ktera vsak neudava"
530 PRINT"severni smer, ale jine svetove"
535 PRINT"strany (J, Z, V)."
540 PRINT: PRINT"Ostatni postup zustava stejny"
545 PRINT"jako drive."
560 GOSUB 790:RETURN
600 REM text 2
610 PRINT: PRINT"**  DRUHA SERIE ULOH"
615 PRINT: PRINT"Kruh je oznacen stejne jako"
620 PRINT"v predchozich ulohach. Meni se"
625 PRINT"vsak postaveni sipky oznacujici"
630 PRINT"zakladni severni smer. Je to"
635 PRINT"podobne, jako kdyz pracujeme"
640 PRINT"s mapou v terenu - drzime ji"
645 PRINT"podle potreby severem k sobe"
650 PRINT"nebo od sebe, jindy smeruje"
655 PRINT"sever doleva apod.":GOSUB 790
660 CLS:PRINT: PRINT"Pri urceni azimutu vychazime"
665 PRINT"vzdy z jine situace, dane"
670 PRINT"polohou sipky. Volbu segmentu"
675 PRINT"provadime stejne jako drive."
680 GOSUB 790:RETURN
700 REM text 1
710 PRINT: PRINT"*  PRVNI SERIE ULOH"
715 PRINT: PRINT"Za chvili se na obrazovce"
717 PRINT"objevi kruh s osmi segmenty A-H"
720 PRINT"a vlevo od nej SEVERNI SMER"
723 PRINT"ve tvaru sipky. V pravem hornim"
725 PRINT"rohu se budou postupne"
728 PRINT"objevovat azimuty.": GOSUB 790
730 CLS:PRINT:PRINT"Jakmile budes vedet, do ktereho"
733 PRINT"segmentu by azimut ze stredu"
735 PRINT"smeroval, stiskni tlacitko"
738 PRINT"pismene, kterym je tento"
740 PRINT"segment oznacen. Pak stiskni"
742 PRINT"tlacitko CR."
745 PRINT"V pravem dolnim rohu se objevi"
750 PRINT"hodnoceni tve odpovedi. "
752 GOSUB 790
755 CLS:PRINT:PRINT"Po splneni vsech deseti ukolu"
760 PRINT"ti pocitac oznami pocet"
765 PRINT"spravnych odpovedi a zepta se,"
770 PRINT"zda chces tuto serii uloh"
775 PRINT"zopakovat."
780 GOSUB 790:RETURN
790 WAIT(10):GOSUB 890
792 PRINT&28,0;"Po precteni stiskni tlacitko CR"
794 IF INKEY$="" THEN 794
796 RETURN
800 REM kruznice
810 E=PI/60: F=2*PI: R=20
820 FOR N=0 TO F STEP E
830 PLOT R*COS(N)+30, R*SIN(N)+34: NEXT N
840 FOR N=10 TO 50
845 PLOT N,34:PLOT 30,N+4: NEXT N
850 FOR N=16 TO 44
855 PLOT N,N+4:PLOT N,64-N: NEXT N
860 PRINT&7,18"A";&12,22"B";&18,22"C"
865 PRINT&22,18"D";&22,11"E";&18,7"F"
870 PRINT& 12,7"G";&7,11"H"
880 RETURN
890 CALL HEX(F973):RETURN
900 REM nacteni poli
905 FOR I=1TO 10
910 READ Z(I):READ S(I)
915 NEXT I
920 DATA 335,72,200,69,160,68,25,65,260,70
925 DATA 80,66,235,70,290,71,155,68,105,67
930 RETURN
950 REM nahoda
960 FOR I=0 TO PEEK(8)
970 A=RND(0): NEXT I
980 RETURN
1000 REM azimut
1005 POKE 20,1:GOSUB 800
1010 H=0: GOSUB 950: D=INT(RND(0)*8)
1020 FOR I=1 TO 10
1030 IF V=1 THEN W=0:P=0:GOTO 1100
1040 IF V=2 THEN W=0:P=INT(RND(0)*7)+1:GOTO 1100
1050 W=INT(RND(0)*3)+1:P=2*W
1060 IF W=1 THEN S$="Z"
1070 IF W=2 THEN S$="J"
1080 IF W=3 THEN S$="V"
1090 PRINT&2,2;S$
1100 GOSUB 400
1110 AN=Z(I)+D*45
1120 IF AN>360 THEN AN=AN-360:GOTO 1120
1130 T=S(I)+D+P
1140 IF T>72 THEN T=T-8:GOTO 1140
1150 PRINT&2,10"AZIMUT (stupnu): ";AN
1155 PRINT&4,22;"Ukol ";I
1160 GOSUB 890:PRINT&28,0: INPUT"SEGMENT ";P$
1170 IF P$=CHR$(T) THEN 1190
1180 PRINT&28,16"CHYBA (";CHR$(T);")" :GOTO 1200
1190 PRINT&28,16"SPRAVNE": H=H+1
1200 WAIT(25):GOSUB 300
1210 NEXT I:POKE 20,2
1220 CLS:PRINT&4,0"        H O D N O C E N I"
1230 PRINT: PRINT"Z deseti uloh jsi splnil  ";H
1235 PRINT"Tva uspesnost je  ";H*10;" %"
1240 IF H>9-V THEN 1260
1250 PRINT: PRINT"MEL BY SIS TEST ZOPAKOVAT !!!"
1260 PRINT&25,0"Opakovani testu      ... 1"
1270 PRINT"Pokracovani          ... 0"
1280 IF INKEY$="1" THEN CLS: GOSUB 1000
1290 IF INKEY$<>"0" THEN 1280
1300 CLS: RETURN
1350 PRINT"XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX"
1355 PRINT: PRINT"          KONEC  TESTU"
1360 PRINT: PRINT"XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX"
1430 PRINT:PRINT"Pokud jsi zvladl kazdou ze tri"
1440 PRINT"casti predlozeneho testu"
1450 PRINT"aspon na  80 %, pujde ti dobre"
1460 PRINT"prakticka orientace podle"
1470 PRINT"azimutu":WAIT(10):GOSUB890
1480 PRINT&25,0;"NOVY TEST   ... 1"
1490 PRINT"KONEC       ... 0"
1500 IF INKEY$="1" THEN RESTORE:GOTO 150
1510 IF INKEY$<>"0" THEN 1500